طريقة إخفاء شاشة الاكسس

[فيصل الحربي]

السلام عليكم ورحمة الله وبركاته

إليكم طريقة إخفاء شاشة الأكسس نهائيا بعد فتح النموذج المطلوب

1- انشئ قاعدة بيانات جديده

2- انسخ الكود التالي ثم الصقه في وحده نمطيه جديدة وسمها أي اسم ترغب به

الكود

===============================================

Option Compare Database

Option Explicit


Global Const SW_HIDE = 0

Global Const SW_SHOWNORMAL = 1

Global Const SW_SHOWMINIMIZED = 2

Global Const SW_SHOWMAXIMIZED = 3


Private Declare Function apiShowWindow Lib "user32" _

    Alias "ShowWindow" (ByVal hwnd As Long, _

          ByVal nCmdShow As Long) As Long


Function fSetAccessWindow(nCmdShow As Long)

'Usage Examples

'Maximize window:

'       ?fSetAccessWindow(SW_SHOWMAXIMIZED)

'Minimize window:

'       ?fSetAccessWindow(SW_SHOWMINIMIZED)

'Hide window:

'       ?fSetAccessWindow(SW_HIDE)

'Normal window:

'       ?fSetAccessWindow(SW_SHOWNORMAL)

'

Dim loX  As Long

Dim loForm As Form

    On Error Resume Next

    Set loForm = Screen.ActiveForm

    If Err <> 0 Then 'no Activeform

      If nCmdShow = SW_HIDE Then

        'MsgBox "Cannot hide Access unless " _

                    & "a form is on screen"

      Else

        loX = apiShowWindow(hWndAccessApp, nCmdShow)

        Err.Clear

      End If

    Else

        If nCmdShow = SW_SHOWMINIMIZED And loForm.Modal = True Then

            'MsgBox "Cannot minimize Access with " _

                    & (loForm.Caption + " ") _

                    & "form on screen"

        ElseIf nCmdShow = SW_HIDE And loForm.PopUp <> True Then

            'MsgBox "Cannot hide Access with " _

                    & (loForm.Caption + " ") _

                    & "form on screen"

        Else

            loX = apiShowWindow(hWndAccessApp, nCmdShow)

        End If

    End If

    fSetAccessWindow = (loX <> 0)

End Function

=============================================== 3- انشئ نموذج جديد وسمه اي اسم ترغب به 4- غير خصائص النموذج الى pop up=yes modal=yes 5- ضع زر امر لإغلاق النموذج مع الأكسس 6- ضع في حدث عند الفتح الكود التالي الكود ==============================================

  fSetAccessWindow (SW_SHOWMINIMIZED)

    fSetAccessWindow (SW_HIDE)

==============================================

7- من قائمة أدوات اختر بدء التشغيل ثم حدد النموذج لكي يفتح في بدء التشغيل

8- إحفظ عملك ثم قم بإنهاء القاعدة .

9- شغل القاعدة وسوف ترى ان خلفية الأكسس مختفيه تماما ما عدا النموذج الذي اخترته من قائمة بدء التشغيل .

10 -دعواتكم لنا بالتوفيق

مرفق مثال على الطريقة

======================

تحياتي

hideaccesswindow.zip

[امير عاطف]

مشكور اخ فيصل على هذا الجهد المعروف به دائماً :yess:

هناك ايضا حل آخر لإخفاء نافذة الاكسس أو اظهارها !!!!!!

وهو عن طريق وضع هذا الكود في وحدة نمطيه

Public Declare Function ShowWindow Lib "user32.dll" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long

Public Sub HideAccess()

Call ShowWindow(Access.hWndAccessApp, 0)

End Sub

Public Sub ShowAccess()

Call ShowWindow(Access.hWndAccessApp, 5)

End Sub

وبعد ذلك في حالة وضع زر مثلاً لإخفاء نافذة الأكسس يتم كتابة

HideAccess

فقط عند حدث النقر لزر الأمر واذا اردنا اظهار نافذة الأكسس يتم كتابة

ShowAccess

عند حدث زر الأمر

وهذا مثال على ذلك مع المرفقات

Hide_Show_AccessWindow.zip

[امير عاطف]

يجب الانتباه الى شيء هام وهو كما قال فيصل الحربي

تغير خصائص النموذج الى

pop up=yes

modal=yes