تغيير أيقونة النموذج

[mohammed55]

ماهي الطريقة لتغيير ايقونة النموذج؟؟

شكراً

[الدكتور خضر الرجبي]

السلام عليكم

أخي mohammed55 ، بارك الله فيك

أعتقد أنه لا يوجد طريقة مباشرة من التحكم أو تغيير خصائص النموذج ، ولكني متأكد من وجود ActiveX لتفيذ المطلوب وهو تغيير أيقونة النموذج ، ويجب البحث.

وذلك أن المطلوب يتعلق بنماذج ألاكسيس أو غيرها.

مع الاحترام.

[Daniello]

السلام عليكم ورحمة الله تعالى وبركاته

لقد عدت إلى المنتدى بعد طول غياب

بلى هناك طريقة أخي خضر وبدون الحاجة إلى ActiveX

وهي أن يوضع الكود التالي في وحدة نمطية

Option Compare Database

Private Declare Function LoadImage Lib "user32" _
   Alias "LoadImageA" _
   (ByVal hInst As Long, _
   ByVal lpsz As String, _
   ByVal un1 As Long, _
   ByVal n1 As Long, _
   ByVal n2 As Long, _
   ByVal un2 As Long) _
   As Long

Private Declare Function SendMessage Lib "user32" _
   Alias "SendMessageA" _
   (ByVal hWnd As Long, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   LParam As Any) _
   As Long

Private Declare Function GetSystemMetrics Lib "user32" (ByVal nIndex As Long) As Long

Private Const WM_SETICON = &H80
Private Const IMAGE_ICON = 1
Private Const LR_LOADFROMFILE = &H10
Private Const SM_CXSMICON    As Long = 49
Private Const SM_CYSMICON    As Long = 50

Public Function SetFormIcon(hWnd As Long, strIconPath As String) As Boolean
    Dim lIcon As Long
    Dim lResult As Long
    Dim X As Long, Y As Long

    X = GetSystemMetrics(SM_CXSMICON)
    Y = GetSystemMetrics(SM_CYSMICON)
    lIcon = LoadImage(0, strIconPath, 1, X, Y, LR_LOADFROMFILE)
    lResult = SendMessage(hWnd, WM_SETICON, 0, ByVal lIcon)
End Function

ويوضع الكود التالي بالنموذج عند حدث الفتح

Private Sub Form_Open(Cancel As Integer)
   SetFormIcon Me.hWnd, "C:\MyIcon.ico"
End Sub

أتمنى أن تكون إجابتي واضحة

ووفقنا الله وإياكم لما فيه خير لمنتدانا الغالي على قلوبنا

والسلام

تم تعديل مارس 4, 2005 بواسطه Daniello

[الدكتور خضر الرجبي]

السلام عليكم

أخي Daniello ، بارك الله فيك

شكرا لك، طريقة رائعة وأكيدة ، جربتها وهي تعمل 100% .

سعيدٌ جدا بعودتك ، وبالتعرف عليك ، أتمنى أن تبقى معنا وتساندنا دائماً.

وبالبحث في الانترنت وجدت ActiveX أسمه Animation Form Icon Control وهو بالإضافة إلى تغيير الايقونة يجعلها متحركة.

ولعلمك أن ما وضعته من كود ، هو بحد ذاته كود ActiveX. والاختلاف بينه وبين ActiveX الذي نطلبه في نموذج الاكسيس هو أن هذه الكود مفتوح (ليس سريا).

مع احترامي وتقديري.

تم تعديل مارس 4, 2005 بواسطه خضر الرجبي