مساعدة مجتاج كود VBA لاظهار شيت مخفي

[matrex 30]

مساعدة محتاج كود VBA لاظهار شيت مخفي

تم رفـــع الملف

مثال (1).xlsm

[Ali Mohamed Ali]

من فضلك اخى الكريم لا تبخل بنجاح المشاركة فليس هناك وجود لأى مشاركة الا بعد تدعيمها بملف مشروح فيه كل المطلوب بكل دقة والا فكان عليك لزاماً استخدام خاصية البحث بالمنتدى قبل رفع هذه المشاركة طالما انك لم تقم برفع ملف !!!

ولا تقول ان المشاركة بسيطة لا تحتاج لكل هذا ... فان كان طلبك بسيط لأستطعت انت بنفسك حله ولا احتجت لمساعدة الأخرين فى حل مشكلتك وتفريج كربتك

تفضل هذا الكود

Sub Unhide_All_Sheets()
    Dim ws As Worksheet
        ActiveWorkbook.Unprotect
    For Each ws In Worksheets
        ws.Visible = xlSheetVisible
    Next
End Sub

وهذا كود أخر

Sub Unhide_All_Sheets_Count()
    Dim wks As Worksheet
    Dim count As Integer
     count = 0
     For Each wks In ActiveWorkbook.Worksheets
        If wks.Visible <> xlSheetVisible Then
            wks.Visible = xlSheetVisible
            count = count + 1
        End If
    Next wks
     If count > 0 Then
        MsgBox count & " worksheets have been unhidden.", vbOKOnly, "Unhiding worksheets"
    Else
        MsgBox "No hidden worksheets have been found.", vbOKOnly, "Unhiding worksheets"
    End If
End Sub

وهذا كود ثالث

Sub Unhide_Selected_Sheets()
    Dim wks As Worksheet
    Dim MsgResult As VbMsgBoxResult
     For Each wks In ActiveWorkbook.Worksheets
        If wks.Visible = xlSheetHidden Then
            MsgResult = MsgBox("Unhide sheet " & wks.Name & "?", vbYesNo, "Unhiding worksheets")
            If MsgResult = vbYes Then wks.Visible = xlSheetVisible
        End If
    Next
End Sub

وهذا كود رابع

Sub Unhide_Sheets_Contain()

    Dim wks As Worksheet

    Dim count As Integer

 

   count = 0

    For Each wks In ActiveWorkbook.Worksheets

        If (wks.Visible <> xlSheetVisible) And (InStr(wks.Name, "report") > 0) Then

            wks.Visible = xlSheetVisible

            count = count + 1

        End If

    Next wks

 

    If count > 0 Then

        MsgBox count & " worksheets have been unhidden.", vbOKOnly, "Unhiding worksheets"

    Else

        MsgBox "No hidden worksheets with the specified name have been found.", vbOKOnly, "Unhiding worksheets"

    End If

End Sub

اختر منهم ما يناسبك

عرفت ان كده اهدار للوقت لأنك لم تقم من البداية برفع الملف فالخطأ عندك ,فالملف لم تقم بوضع اى كود به-تفضل بعد وضع الكود يعمل بكل كفاءة

 

مثال.xlsm