مساعده في كود فتح برنامج الاوتلوك عند الضغط على بريد الزبون

[Radwan0]

السلام عليكم اخواني

في نموذج tbl عند الضغط مرتين على حقل البريد فانه يقوم بفتح برنامج الاوتلوك 

الى الان الكود يعمل بشكل سليم لكن حصلت عندي مشكلتين

1) في حال كان حقل الايميل فارغ تظهر لي رسالة خطأ . كيف بالامكان اظهار رسالة تفيد بانه يجب ادخال بريد الكتروني او لا الكود لا يستجيب بفتح الماكرو او الاوتلوك

2) كيف بالامكان جعل نوع الخط ثابت والرسالة تبدا من اليمين وليس من الشمال

 

Option Compare Database

Private Sub mail_DblClick(Cancel As Integer)
    Dim Msg As String
    Msg = " hey " & namecus & "<p>"
    
   
  Dim O As Outlook.Application
  Dim M As Outlook.MailItem
  
  Set O = New Outlook.Application
  Set M = O.CreateItem(olMailItem)
  
  With M
    .BodyFormat = olFormatHTML
    .HTMLBody = Msg
    '.Body = txt - if you see olformatplain
    .To = mail
    '.CC="khate9191@gmail.com;khateb91@outlook.com"
    '.BCC="hateeb991@gmail.com"
    .Subject = " new mail " & Now()
    .Display
    '.send
   End With
    Set M = Nothing
    Set O = Nothing
End Sub

 

Database1.accdb

[سامي الحداد]

وعليكم السلام 

تفضل اخي جرب الكود واعلمني بالنتيجة لانني لا استخدم الاوتلوك.

Private Sub mail_DblClick(Cancel As Integer)
 Dim Msg As String
    
    If Len(Mail) = 0 Then
        MsgBox "حقل البريد الإلكتروني فارغ. الرجاء إدخال عنوان البريد الإلكتروني "
        Exit Sub
    End If
    
    Msg = "<div style='direction:rtl; font-family:Consolas, Courier;'>" & _
          " hey " & namecus & "<br>" & _
          "</div>"
    
    Dim O As Outlook.Application
    Dim M As Outlook.MailItem
  
    Set O = New Outlook.Application
    Set M = O.CreateItem(olMailItem)
  
    With M
        .BodyFormat = olFormatHTML
        .HTMLBody = Msg
        '.Body = txt - if you see olformatplain
        .To = Mail
        '.CC="khate9191@gmail.com;khateb91@outlook.com"
        '.BCC="hateeb991@gmail.com"
        .Subject = " new mail " & Now()
        .Display
       '.send
    End With
    
    Set M = Nothing
    Set O = Nothing
End Sub

تحياتي

[Radwan0]

شكرا جزيلا اخي العزيز

بالنسبه لنوع الخط واتجاه النص الكود صحيح

بقيت مشكلة حقل البريد فارغ 

يظهر لي الخطا  invalid use of null

[سامي الحداد]

جرب هذا التعديل و وافنا بالنتيجة

Private Sub mail_DblClick(Cancel As Integer)
    Dim Msg As String
    
    If IsNull(Mail) Or Len(Mail) = 0 Then
        MsgBox "حقل البريد الإلكتروني فارغ. الرجاء إدخال عنوان البريد الإلكتروني "
        Exit Sub
    End If
    
    Msg = "<div style='direction:rtl; font-family:Consolas, Courier;'>" & _
          " hey " & namecus & "<br>" & _
          "</div>"
    
    Dim O As Outlook.Application
    Dim M As Outlook.MailItem
  
    Set O = New Outlook.Application
    Set M = O.CreateItem(olMailItem)
  
    With M
        .BodyFormat = olFormatHTML
        .HTMLBody = Msg
        '.Body = txt - if you see olformatplain
        .To = Mail
        '.CC="khate9191@gmail.com;khateb91@outlook.com"
        '.BCC="hateeb991@gmail.com"
        .Subject = " new mail " & Now()
        .Display
       '.send
    End With
    
    Set M = Nothing
    Set O = Nothing
End Sub

تحياتي

[Radwan0]

وهو المطلوب

باركك الرحمن تعالى

 

[سامي الحداد]

7 ساعات مضت, Radwan0 said:

وهو المطلوب

باركك الرحمن تعالى

 

الله ييارك فيك اخي الكريم.