إخفاء وإظهار ايقونات سطح المكتب

[TQTHAMI]

السلام عليكم ورحمة الله وبركاته

اسعد الله اوقاتكم بالسعادة والسرور

هل يوجد كود لإخفاء واظهار ايقونات سطح المكتب  

[محمد احمد لطفى]

تفضل بالتوفيق 

 

Show Hide Icon Desk Top.mdb

[TQTHAMI]

يسعد مساءك استاذ محمد

للأسف لا يعمل عندي

تم تعديل مايو 6 بواسطه TQTHAMI

[Foksh]

13 دقائق مضت, TQTHAMI said:

للأسف يعمل عندي

الكود يعمل معي على نسخة ويندوز 10 وإصدار أوفيس 64 ، ولكن يبدو انك بحاجة لإضافة PtrSafe لتحويل الكود للعمل على إصدار 64 .

والشكر للأستاذ @محمد احمد لطفى على فكرته الجميلة

وهذه فكرته لا أتعدى عليه ولا أحصد ثمر مجهوده الثمين ، وإنما بلمستي 

Hide Icon Desktop.accdb

[TQTHAMI]

تحية عطره لكم 

ولكن نفس الشي لا يعمل 

[Foksh]

3 دقائق مضت, TQTHAMI said:

ولكن نفس الشي لا يعمل 

غريب ، هذا هو كود الأستاذ @محمد احمد لطفى ، من جهازي

ما هو اصدار الويندوز والأوفيس لديك ؟

 

20240506_170555.zip

[ابو جودي]

50 دقائق مضت, Foksh said:

ما هو اصدار الويندوز والأوفيس لديك ؟

 

طيب مشاركة مع اخوانى الكرام واساتذتى الافاضل بعد التعديلات على الاكواد

#If VBA7 Then
    #If Win64 Then
        Private Declare PtrSafe Function GetWindow Lib "user32" (ByVal hWnd As LongPtr, ByVal wCmd As Long) As LongPtr
        Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
        Private Declare PtrSafe Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, lParam As Any) As LongPtr
    #Else
        Private Declare PtrSafe Function GetWindow Lib "user32" (ByVal hWnd As Long, ByVal wCmd As Long) As Long
        Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
        Private Declare PtrSafe Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
    #End If
#Else
    Private Declare Function GetWindow Lib "user32" (ByVal hWnd As Long, ByVal wCmd As Long) As Long
    Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
#End If

Private Const GW_CHILDREN As Long = 5
Private Const WM_COMMAND As Long = &H111

Private Sub Btn_Hide_Click()
    Dim toggleDesktopCommand As Long
    Dim hWnd As LongPtr

    toggleDesktopCommand = &H7402
    hWnd = FindWindow("Progman", "Program Manager")

    If hWnd <> 0 Then
        hWnd = GetWindow(hWnd, GW_CHILDREN)
        If hWnd <> 0 Then
            SendMessage hWnd, WM_COMMAND, toggleDesktopCommand, ByVal 0&
            If Btn_Hide.Caption = "Hide Icon" Then
                Me.Btn_Hide.Caption = "Show Icon"
                Me.Caption = " Desktop Icon Hide"
            Else
                Me.Btn_Hide.Caption = "Hide Icon"
                Me.Caption = " Desktop Icon Show"
            End If
        Else
            MsgBox "Failed to find child window of Program.", vbExclamation
        End If
    Else
        MsgBox "Failed to find Program window.", vbExclamation
    End If
End Sub

Private Sub Form_Load()
    Me.Caption = ""
End Sub

 

Hide Icon Desktop.accdb

[Moosak]

3 ساعات مضت, ابو جودي said:

طيب مشاركة مع اخوانى الكرام واساتذتى الافاضل بعد التعديلات على الاكواد

هذا يعمل عندي بكفاءة 👍🏻

[TQTHAMI]

السلام عليكم ورحمة الله وبركاتة 

لاستطيع تجربة المثال لاني خارج المنزل من امس 

ولكن سوف اكون هناك بعد غد واشوفه 

ووعموما الشكر والتقدير للجميع 

 

[TQTHAMI]

السلام عليكم ورحمة الله وبركاته
اسعد  الله أوقانكم بالخير 
اولا 
الاخ العزيز ابو جودي
اعتذر عن التأخير على الرد لمشاغل الحياة التي لاتنتهي
قمت بتجربت الكود وظهرت لي هذي الرسالة
 ولا اعلم جميع الأخوة الذي شاركوا في هذا الموضوع يفيدون بعمله بنسبة 100%
علما ان الوندوز ١٠  والأوفيس 365

[Foksh]

أخي @TQTHAMI ، للمحاولة جرب هذا المرفق والكود :-

Option Compare Database
Option Explicit

#If Win64 Then
    Private Declare PtrSafe Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As LongPtr, ByVal hWnd2 As LongPtr, ByVal lpsz1 As String, ByVal lpsz2 As String) As LongPtr
    Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
    Private Declare PtrSafe Function ShowWindow Lib "user32" (ByVal hWnd As LongPtr, ByVal nCmdShow As Long) As Long
#Else
    Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
    Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    Private Declare Function ShowWindow Lib "user32" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long
#End If

Private Const SW_HIDE As Long = 0
Private Const SW_SHOW As Long = 5

Public Sub HideDesktopIcons()
    Dim hWndProgMan As LongPtr
    Dim hWndSHELLDLL_DefView As LongPtr
    Dim hWndSysListView32 As LongPtr
    hWndProgMan = FindWindow("Progman", vbNullString)
    hWndSHELLDLL_DefView = FindWindowEx(hWndProgMan, 0, "SHELLDLL_DefView", vbNullString)
    hWndSysListView32 = FindWindowEx(hWndSHELLDLL_DefView, 0, "SysListView32", "FolderView")
    ShowWindow hWndProgMan, SW_HIDE
    ShowWindow hWndSHELLDLL_DefView, SW_HIDE
    ShowWindow hWndSysListView32, SW_HIDE
End Sub

Public Sub ShowDesktopIcons()
    Dim hWndProgMan As LongPtr
    Dim hWndSHELLDLL_DefView As LongPtr
    Dim hWndSysListView32 As LongPtr
    hWndProgMan = FindWindow("Progman", vbNullString)
    hWndSHELLDLL_DefView = FindWindowEx(hWndProgMan, 0, "SHELLDLL_DefView", vbNullString)
    hWndSysListView32 = FindWindowEx(hWndSHELLDLL_DefView, 0, "SysListView32", "FolderView")
    ShowWindow hWndProgMan, SW_SHOW
    ShowWindow hWndSHELLDLL_DefView, SW_SHOW
    ShowWindow hWndSysListView32, SW_SHOW
End Sub

Private Sub Btn_Hide_Click()
    If Btn_Hide.Caption = "Hide Icon" Then
        HideDesktopIcons
        Me.Btn_Hide.Caption = "Show Icon"
        Me.Caption = " Desktop Icone Hide"
    Else
        ShowDesktopIcons
        Me.Btn_Hide.Caption = "Hide Icon"
        Me.Caption = " Desktop Icone Show"
    End If
End Sub

Hide Icon Desktop - 2.accdb

[محمد القدسي]

بارك الله فيكم اساتذتي وبارك في علمكم اجمعين

طيب اساتذتي هل بالامكان اخفاء ايقونه محدده 

يعني اريد اخفي ايقونه محدده بحسب الاسم والنوع من سطح المكتب وليس اخفاء جميع الايقونات

[TQTHAMI]

السلام عليكم ورحمة الله وبركاتة

اخي Foksh  تحية عطرة 

للأسف نفس الشيء لا يعمل 

 

[Foksh]

56 دقائق مضت, TQTHAMI said:

السلام عليكم ورحمة الله وبركاتة

اخي Foksh  تحية عطرة 

للأسف نفس الشيء لا يعمل 

 

بناءً عليه فإن المشكلة في تحديثات الأوفيس365 لديك.

منذ ساعه, محمد القدسي said:

بارك الله فيكم اساتذتي وبارك في علمكم اجمعين

طيب اساتذتي هل بالامكان اخفاء ايقونه محدده 

يعني اريد اخفي ايقونه محدده بحسب الاسم والنوع من سطح المكتب وليس اخفاء جميع الايقونات

🤗 سؤال جميل ، وأعتقد أنه ممكن ذلك 

[TQTHAMI]

السلام عليكم ورجمة الله وبركاتة

اخي العزيز Foksh

((بناءً عليه فإن المشكلة في تحديثات الأوفيس365 لديك.))

بناءا على ما ذكرته قمت بحذف الاوفيس واعدة تنصيبه 

و لازالت المشكلة 

[Foksh]

9 دقائق مضت, TQTHAMI said:

قمت بحذف الاوفيس واعدة تنصيبه

هل جربت تنصيب اوفيس 2019 أو 2016 ؟