مشكلة بكود VBA

[figo82eg]

ارجو المساعدة حيث لدى كود فتح مستندات PDF داحل فولدر بمسارقاعدة البيانات الكود يعمل بشكل ممتاز عدا جزئية خطيرة بالنسبة لى وهى :

عند يكون الحقل المربوط به زر فتح المستند خالى من البيانات يقوم الكود بفتح جميع المستندات داخل الفولدر وبالتالى لدى الاف المستندات مخزنة داخل الفولدر مما يجعل الجهاز يهنج

الكود كالتالى :

ارجو التعديل عليه للتغلب على هذه المشكلة

Private Sub OpenFiles_Click()
'Dim File_Path As String, File_Name As String, Name_Path As String
   File_Path = Application.CurrentProject.path & "\Edit\"

   File_Name = Dir(File_Path & Me.رقم_الخطاب & "*.pdf")
   
   If File_Name = "" Then
     DoCmd.OpenForm "sms1", acMaximize
      Exit Sub
   End If
   While File_Name <> ""
      Name_Path = File_Path & File_Name
      Application.FollowHyperlink Name_Path
      File_Name = Dir()
   Wend
End Sub

 

تم تعديل أغسطس 4, 2024 بواسطه figo82eg

[Foksh]

تفضل اخي الكريم @figo82eg

 

هذا التعديل يتأكد مما اذا كان هناك ملف بنفس رقم الخطاب الحالي أو لا . وأيضاً من أن مربع النص "رقم الخطاب" غير فارغ .

Private Sub OpenFiles_Click()
    If IsNull(Me.رقم_الخطاب) Or Me.رقم_الخطاب = "" Then
        MsgBox "الرجاء إدخال رقم الخطاب.", vbExclamation, "خطأ"
        Exit Sub
    End If

    Dim File_Path As String, File_Name As String, Name_Path As String
    File_Path = Application.CurrentProject.path & "\Edit\"

    File_Name = Dir(File_Path & Me.رقم_الخطاب & "*.pdf")
   
    If File_Name = "" Then
        MsgBox "ملف الخطاب غير موجود.", vbInformation, "تنبيه"
        DoCmd.OpenForm "sms1", acMaximize
        Exit Sub
    End If

    While File_Name <> ""
        Name_Path = File_Path & File_Name
        Application.FollowHyperlink Name_Path
        File_Name = Dir()
    Wend
End Sub

 

[figo82eg]

شكراُ استاذى الكريم هو المطلوب