مساعد لمعرفه من لديه ملف بي دي

[Majed_ali2010]

السلام وعليكم ورحمه الله وبركاته

لدي مجلد يحتوي على ملفات بي دي اف مسماه برقم الموضف اريد كود في زر امر عند النقر عليه يضع كلمه نعم بالحقل الموضح المثال المرفق ولكنFILE.rarFILE.rarFILE.rarFILE.rar فقط للذي لديه ملف بالمجلد

FILE.zip

[Foksh]

وعليكم السلام ورحمة الله وبركاته ،،

أخي الكريم يوجد أكثر من طريقة واسلوب وحل ، ولكن قبل الشروع بذكر أحدها سأنصحك نصيحة متفرعة =

1. الإبتعاد عن التسميات العربية للجداول والحقول والنماذج ومكوناتها .
2. عدم استخدام "-" في التسميات ، والأفضل استخدام "_" إن كنت مضطراً .

الآن في النموذج سنقوم بحذف جميع الأكواد ولا حاجة لها ولا حاجة للزر أيضاً ، ثم في مديول جديد ألصق الكود التالي :-

Public Sub UpdateEmployeeFiles()
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim strPath As String
    Dim strFileName As String
    
    strPath = CurrentProject.Path & "\"
    
    Set db = CurrentDb
    Set rs = db.OpenRecordset("جدول1", dbOpenDynaset)
    
    If Not rs.EOF Then
        rs.MoveFirst
        Do Until rs.EOF
            strFileName = strPath & rs!رقم_الموضف & ".pdf"
            
            rs.Edit
            If Dir(strFileName) <> "" Then
                rs!لديه_ملف = "نعم"
                rs!مسار_الملف = strFileName
            Else
                rs!لديه_ملف = "لا"
                rs!مسار_الملف = Null
            End If
            rs.Update
            
            rs.MoveNext
        Loop
    End If
    
    rs.Close
    Set rs = Nothing
    Set db = Nothing
End Sub

وفي النموذج يكفينا الإستدعاء للدالة في حدث عند التحميل كما يلي :-

Private Sub Form_Load()
    UpdateEmployeeFiles
End Sub

 

حيث أن الدالة ستقوم بتحديث قيمة الحقل في كل مرة تفتح فيها النموذج للموظفين الذين لديهم ملف PDF أو لا . أيضاً سيتم تعديل مسار الملف اذا كان موجوداً بدلاً من استخدامك للكود السابق في حدث "في الحالي" .

 

 

FILE.zip

[أبو إبراهيم الغامدي]

وعليكم السلام ورحمة الله وبركاته

أهلا بك..

الطريقة التالية تقوم أولا بالتحقق من مسار الملف ، ثم التحقق من وجود الملف. وذلك عن طريق حدث السجل الحالي

Private Sub Form_Current()
   '--تحقق مسار الملف
   مكان_الملف = "D:\FILE\"
   مسار_الملف = IIf(Len(Dir(مكان_الملف)), مكان_الملف, CurrentProject.Path & "\") & Me.رقم_الموضف & ".PDF"
   
   '-- تحقق من وجود الملف
   Me.لديه_ملف = IIf(Len(Dir(مسار_الملف)), "نعم", "لا")
      
End Sub

FILE.zip

[Majed_ali2010]

اخي و استاذي @أبو إبراهيم الغامدي

اولا لكم مني جزيل الشكر على مرورك الكريم وسرعة الاستجابه

هذا بالفعل هوا المطلوب 

[Majed_ali2010]

اخي واستاذي @Foksh

اولا لكم مني جزيل الشكر على مرورك الكريم وسرعة الاستجابه

هذا بالفعل هوا المطلوب