مساعده في كود تحديث سجلات

[Bshar]

السلام عليكم ورحمة الله ,

الرجاء المساعده في نموذج efkt  عند الضغط  على زر ادخال  يعمل على تحديث السجل الاول فقط با انقاص الرصيد   وباقي السجلات المشار عليها true يبقى الرصيد كما هوه . . شاكرا لكم خدمتكم

مرفق

stor.accdb

[Foksh]

42 دقائق مضت, Bshar said:

السلام عليكم ورحمة الله ,

 

وعليكم السلام ورحمة الله وبركاته أخي بشار ..

بعد تجربة المرفق ، يتم انقاص قيمة الكمية من السجل الأول فقط في ملفك المرفق ..

أو يمكنك التوضيح اكثر ليتم فهم المطلوب بشكل جيد عن القيمة المطلوب انقاصها من السجل الأول !!!!

[Bshar]

اهلا اهلا فوكشش ، طمني عنك مشااان الله ،، مشتقلك صديقي ،،

نعم صحيح يتم انقاص الكميه فقط من سجل الاول ، انا اريد انقاص السجلين الاخرين ايضا، 

[Foksh]

15 دقائق مضت, Bshar said:

اهلا اهلا فوكشش ، طمني عنك مشااان الله ،، مشتقلك صديقي ،،

 

حبيبي يا بشار ، الله يسعدك ، الحمد لله بخير .. انت اللي مختفي يا زلمة  ..

جرب هذا التعديل بحيث انه يمر على كل السجلات ، طبعاً لم يتم تعديل اي فكرة من الاستعلامات الـ 3 اللي انت عاملها ..

Private Sub e2_Click()
    Dim i As Integer
    Dim ctl As Form
    Set ctl = Me.dff.Form

    Dim foundValid As Boolean
    foundValid = False

    For i = 0 To ctl.Recordset.RecordCount - 1
        ctl.Recordset.AbsolutePosition = i
        If ctl.Controls("hgf").Value = True Then
            foundValid = True
            ctl.Controls("c4").Value = Nz(ctl.Controls("c1").Value, 0) - Nz(ctl.Controls("c3").Value, 0)
        End If
    Next i

    If Not foundValid Then
        MsgBox "لم يتم إدخال أدوية - سيتم الخروج الآن", vbExclamation, "إدارية"
        DoCmd.Close
        Exit Sub
    End If

    Me.dff.Requery
    DoCmd.SetWarnings False
    DoCmd.OpenQuery "efkt_aa", acViewNormal
    DoCmd.OpenQuery "del_efktc", acViewNormal
    DoCmd.OpenQuery "ry", acViewNormal
    DoCmd.SetWarnings True

    Me.Requery
    Me.Refresh
    Me.e2.Enabled = False

    MsgBox "تم بنجاح", vbInformation, "إدارية"
    DoCmd.Close
    DoCmd.OpenForm "efkt"
End Sub

 

[Bshar]

@Foksh  قليل اشتغل ع اكسس  عحسب وقت الفراغ ,, المهم فوووكش  ,, اشتغل التعديل 100%  ,, بس اذا  في طريقه او حل غير لانه وقت ضفت 150 سجل   صار مشكله انه عللق الاكسس  وهوه يمر عالسجلات ,, شاكر الك مساعدتي بالمقدمه دائما

[Foksh]

صديقي @Bshar ، جرب هذا التعديل عندك ..
 

Private Sub e2_Click()
    Dim ctl As Form
    Set ctl = Me.dff.Form
    
    Dim foundValid As Boolean
    foundValid = False
    
    With ctl.RecordsetClone
        .MoveFirst
        Do While Not .EOF
            If ctl.Controls("hgf").Value = True Then
                foundValid = True
                Exit Do
            End If
            .MoveNext
        Loop
    End With
    
    If Not foundValid Then
        MsgBox "لم يتم إدخال أدوية - سيتم الخروج الآن", vbExclamation, "إدارية"
        DoCmd.Close
        Exit Sub
    End If
    
    Dim strSQL As String
    strSQL = "UPDATE [" & ctl.RecordSource & "] " & _
            "SET [qunt_x] = Nz([qunt_a], 0) - Nz([qunt_out], 0) " & _
            "WHERE [efkt_b] = True"
            
    DoCmd.SetWarnings False
    DoCmd.RunSQL strSQL
    DoCmd.OpenQuery "efkt_aa", acViewNormal
    DoCmd.OpenQuery "del_efktc", acViewNormal
    DoCmd.OpenQuery "ry", acViewNormal
    DoCmd.SetWarnings True
    
    Me.dff.Requery
    Me.Requery
    Me.Refresh
    
    MsgBox "تم بنجاح", vbInformation, "إدارية"
    DoCmd.Close
    DoCmd.OpenForm "efkt"
End Sub

 

تم تعديل منذ 3 ساعات بواسطه Foksh
تصحيح خطأ في الكود

[Bshar]

@Foksh  يسلم ايدك ✋  ماشالله عليك,,  شغل فاخر عالاخر فوووكش ,, ربي يزيدك علم ويبارك في رزقك ويكفيك شر الناس ,كل الشكر والتقدير لك 

[Foksh]

حبيبي يا بشار ، الله يسعد قلبك ويهنيك ..