عندي موضوع للمناقشة

[sabah19672025]

السلام عليكم

حياكم  الله

هل من الممكن الاتصال بجهاز البصمة ZKTECO دون المرور بالبرنامج ATTENDANCE وسحب

التقارير مباشرة من جهاز البصمة من خلال الاكسل

ارجو ان يكون ممكن

 

تم تعديل منذ 23 ساعات بواسطه sabah19672025

[Foksh]

وعليكم السلام ورحمة الله وبركاته ،،

باعتقادي ما ينطبق على اكسيس يمكن ان ينطبق على اكسل . فأولاً يلزمك تثبيت مكتبة SDK منموقع الشركة ZKTeco من هذه الصفحة هنا ( يلزمك تسجيل الدخول طبعاً للتحميل من الموقع الرسمي ) . حيث انها تحتوي على مكتبة الوظائف التي تسمح بالاتصال المباشر بالجهاز .

بعد تحميل البرنامج من الموقع الرسمي ، قم بتسجيل المكتبة zkemkeeper.dll كما يلي :-

افتح موجه الأوامر CMD كمسؤول ، ثم استخدم السطر التالي مع تعديل مسار الملف السابق حسب مسار التثبيت لديك :-

regsvr32 "C:\المسار\zkemkeeper.dll"

 

ثم قم بإضافة المكتبة بحيث أن تفعّل خيار: zkemkeeper.dll أو ZKEMkeeper 1.0 Type Library

الآن كود VBA بسيط للاتصال بالجهاز :-

Dim zk As New zkemkeeper.CZKEM

Sub ConnectToDevice()
    Dim connected As Boolean
    connected = zk.Connect_Net("192.168.1.201", 4370)
    
    If connected Then
        MsgBox "تم الاتصال بالجهاز بنجاح"
    Else
        MsgBox "فشل الاتصال بالجهاز"
    End If
End Sub

تأكد من عنوان IP الخاص بالجهاز طبعاً .

وهذه دالة لجلب سجلات الحضور :-

Option Explicit

Dim zk As New zkemkeeper.CZKEM

Sub GetAttendanceLogs()
    Dim ip As String: ip = "192.168.1.201" ' لجهاز البصمة لديك  IP غيّر هذا العنوان إلى عنوان 
    Dim port As Long: port = 4370          '  المنفذ الافتراضي عادةً
    Dim iMachineNumber As Long: iMachineNumber = 1
    
    Dim connected As Boolean
    connected = zk.Connect_Net(ip, port)
    
    If Not connected Then
        MsgBox "فشل الاتصال بالجهاز. تحقق من الشبكة أو الإعدادات", vbCritical
        Exit Sub
    End If

    zk.EnableDevice iMachineNumber, False

    If Not zk.ReadGeneralLogData(iMachineNumber) Then
        MsgBox "لا توجد سجلات متاحة ، أو تعذر قراءتها", vbExclamation
        zk.EnableDevice iMachineNumber, True
        zk.Disconnect
        Exit Sub
    End If

    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("Sheet1")
    ws.Cells.ClearContents
    ws.Range("A1:E1").Value = Array("UserID", "DateTime", "State", "Verified", "WorkCode")
    
    Dim userID As Long, verifyMode As Long, inOutMode As Long
    Dim year As Long, month As Long, day As Long
    Dim hour As Long, minute As Long, second As Long
    Dim workCode As Long
    Dim row As Long: row = 2
    
    Do While zk.SSR_GetGeneralLogData(iMachineNumber, CStr(userID), _
              verifyMode, inOutMode, year, month, day, hour, minute, second, workCode)
        
        Dim dt As String
        dt = Format(DateSerial(year, month, day) + TimeSerial(hour, minute, second), "yyyy-mm-dd hh:nn:ss")
        
        ws.Cells(row, 1).Value = userID
        ws.Cells(row, 2).Value = dt
        ws.Cells(row, 3).Value = inOutMode
        ws.Cells(row, 4).Value = verifyMode
        ws.Cells(row, 5).Value = workCode
        row = row + 1
    Loop
    
    zk.EnableDevice iMachineNumber, True
    zk.Disconnect
    
    MsgBox " تم سحب عدد " & row - 2 & " من سجلات الحضور بنجاح", vbInformation
End Sub

 

شرح الأعمدة :-

UserID = رقم الموظف

DateTime = تاريخ ووقت الحضور/الانصراف

State = نوع الحركة (0 = دخول ، 1 = خروج)

Verified = طريقة التحقق (بصمة ، كارت ، كلمة مرور)

WorkCode = رمز العمل (اختياري ، حيث يعتمد على الجهاز)

هذا من وجهة نظري بعد التعديل فيما يتوافق مع اكسل ( مشتق من أكواد آكسيس )

 

ولكم التجربة طبعاً لأنني حالياً لا أملك جهاز البصمة المذكور نوعه سابقاً ..

تم تعديل منذ 11 ساعات بواسطه Foksh
تنسيق الرد

[sabah19672025]

تمام - ساحاول اتباع الخطواتواعلامك بالنتائج = ولكن اصبر عليه - لاني في البيت والجهاز بالدائرة ولدينا عطلة

 

[Foksh]

ولا يهمك اخي الكريم ، خذ راحتك ، واليوم فعلاً انا خارج المنزل وبعيد عن الكمبيوتر الى صباح غد إن شاء الله 🤗😇