الطريقة الصحيحة لجعل المعادلة تعمل بالخلايا دون ترك فراغات

[mohsen mohamed]

خزينة المشتريات والتراخيص المركزية عام 2025-2026.xlsx

السلام عليكم ورحمة الله وبركاته 

أساتذتي الكرام 

الملف المرفق أحاول عمل معادلة لشيت المشتريات والتراخيص بحيث يتم تنزيل الوارد بهما من شيت الوارد ولكن المعادلة تترك بعض الخلايا فارغة بغير تتابع بالخلايا.

أرجو من سيادتكم هل يمكن تحويل الخلايا الخاصة ب المشتريات والتراخيص كل في الشبت الخاص بهما مع عدم ترك فراغات.

وشكرا لحضراتكم.

[Foksh]

10 ساعات مضت, mohsen mohamed said:

السلام عليكم ورحمة الله وبركاته 

 

وعليكم السلام ورحمة الله وبركاته ..

حاولت التبسيط لك من خلال المعادلات و وجدت انك ستقوم بتكرار الكثير من المعادلات لكل عمود . لذا خطرت لي فكرة أبسط لك من خلال الكود التالي في زر  :-

Private Sub CommandButton1_Click()
    Dim wsSrc As Worksheet, wsDest As Worksheet
    Dim srcData As Variant, outData() As Variant
    Dim i As Long, j As Long, outRow As Long
    Dim lastRow As Long
    Set wsSrc = ThisWorkbook.Sheets("الوارد")                       'تحديد الورقة المصدر
    Set wsDest = ThisWorkbook.Sheets("مشتريات")                     'تحديد الورقة الهدف
    lastRow = wsSrc.Cells(wsSrc.Rows.Count, "F").End(xlUp).Row
    srcData = wsSrc.Range("B3:N" & lastRow).Value                   ' تم التوسيع حتى العمود N (عمود 14)
    ReDim outData(1 To UBound(srcData), 1 To 13)                    'تحديد عدد الأعمدة
    outRow = 0
    For i = 1 To UBound(srcData)
        If Trim(srcData(i, 5)) = "مشتريات" Then                     'تحديد الشرط
            outRow = outRow + 1
            For j = 1 To 13                                         'تحديد عدد الأعمدة
                outData(outRow, j) = srcData(i, j)
            Next j
        End If
    Next i
    If outRow > 0 Then
        wsDest.Range("B3").Resize(outRow, 13).Value = outData        'تحديد عدد الأعمدة
    End If
End Sub

 

وأضفت لك التعليقات لتفهم الفكرة في حال أردت التنفيذ على أوراق أو أفكار اخرى بتغيير الشروط والهدف والمصدر والأعمدة .... إلخ

الملف المرفق ، في الورقة "مشتريات" انقر الزر فقط 😁 .

 

 

خزينة المشتريات والتراخيص المركزية عام 2025-2026.xlsm