مساعدة من الاخوة الأفاضل

[abassreda]

السلام عليكم ورحمة الله وبركاته

ده شيت اكسل من عمل احد اساتذتنا فى الادارة التعليمية فيه بيانات طلبة كنت محتاج عمود ولى الأمر لو الاسم مركب زى منه الله محمد ميطلع اسم الاب الله محمد يطلعه محمد ولكم جزيل الشكر 

مجمع 2026بعد نتيجة ثالثة.xlsx

[أبوعيد]

السلام عليكم
عادة ما يتكون الاسماء المركبة بين قوسين هكذا [  ]
ولكن بدون أقواس يكون الأمر فيه شيء من الصعوبة 
المهم يوجد [تكة] صغيرة أو خدعة بسيطة تستطيع أن تحل بها المشكلة .
تابع معي :

منة الله : يتكون من (منة) ثم مسافة ثم (الله)

المسافة هنا هي المشكلة , لذلك سنجعلها (نصف مسافة) وليس مسافة كاملة

منة الله : لو حذفنا المسافة ستكون (منةالله) وهذا هو الاسم السليم لأن (منة) آخرها تاء مربوطة مش هاء 
الآن : لنفترض أن الاسم هو منه الله (بالهاء) كما هو في ملف الاكسل . كيف العمل ؟
منه الله : لو حذفنا المسافة ستكون (منهالله) وهذا غلط
أذن لا نحذف المسافة ولكن نجعلها (نصف مسافة )
منه‌ الله : منه‌الله   هكذا     --- كيف فعلنا هذا ؟ والطريقة بسيطة
اكتب منه ثم (اضغط ctrl+shift+@) ثم اكتب الله

هذه الأزرار الثلاثة لا تعمل بهذه الفكرة إلا في تنسيق الكتابة العربية وليس الأنجليزية
 

تقبل تحياتي

[احمد عبدالحليم]

وعليكم السلام ورحمه الله وبركاته
راجع الملف لعله المطلوب

 

[hegazee]

بارك الله فيك أستاذ أحمد

. كما تفضلت حضرتك بالملف فإن معادلة العلامة خبور رائعة و تصلح لهذا الملف تماما فقط قم بنسخ الكود التالي في موديل جديد في  في محرر الأكواد

Function kh_Names(FullName As String, ParamArray iNdex1()) As String
Dim i As Integer
Dim kh_Split, MyArray, Ar
Dim Kh_String As String, Sn As String, Re As String
    
On Error GoTo Err_Kh_Names

    '======================================
    MyArray = Array("عبد ", "أبو ", "ابو ", "آل " _
    , " الله", " الدين", " الإسلام", " الاسلام", " الحق")
    '======================================
    Sn = Application.WorksheetFunction.Trim(FullName)
    For Each Ar In MyArray
        Re = Replace(Ar, " ", "^")
        Sn = Replace(Sn, Ar, Re)
    Next
    '======================================
    kh_Split = Split(Sn, " ", , vbTextCompare)
    
    On Error Resume Next
    For i = 0 To UBound(iNdex1)
        Kh_String = Kh_String & " " & kh_Split(iNdex1(i) - 1)
    Next
    On Error GoTo 0
    
    Kh_String = Replace(Trim(Kh_String), "^", " ")
    kh_Names = Kh_String
    
    Exit Function

Err_Kh_Names:
     kh_Names = ""
End Function

ثم  ضع المعادلة التالية في خانة اسم الأب مثلا:

=kh_Names(H9;2;3;4;5)

مع مراعاة الفاصلة عادية أو منقوطة حسب اصدار الاوفيس

مجمع 2026بعد نتيجة ثالثة.xlsm