دمج قيم حقل في نموذج مستمر داخل مربع نص

[at_aziz]

السلام عليكم ورحمة الله وبركاته

اخواني 

كيف ادمج  حقول عمود نصية  في نموذج مستمر 

في مربع نص واحد

كماهو موضح بالصوره

ارجو المساعده بارك الله فيكم وجزاكم خير

TEST1.accdb

[Foksh]

وعليكم السلام ورحمة الله وبركاته ,,

هل هذا المقصود من طلبك ؟

 

 

[at_aziz]

نعم صحيح   هذا المطلوب

[Foksh]

حسناً ..

سأقدم لك حلين اثنين ، ولربما سيكون هناك حلول أخرى من الأخوة والساتذة والمعلمين ..

الأول :-

باستخدام الدالة البسيطة التالية :-

Public Function Foksh_TXTK1() As String
    Dim rs As DAO.Recordset
    Dim result As String
    Set rs = CurrentDb.OpenRecordset("SELECT TXTK1 FROM Tablek WHERE TXTK1 Is Not Null", dbOpenSnapshot)
    Do While Not rs.EOF
        If rs!TXTK1 <> "" Then
            result = result & rs!TXTK1 & " , "
        End If
        rs.MoveNext
    Loop
    If Len(result) > 3 Then
        result = Left(result, Len(result) - 3)
    End If
    Foksh_TXTK1 = result
    rs.Close
    Set rs = Nothing
End Function

مع استخدام استعلام ليكون مصدر سجلات النموذج ، كمثال :-

SELECT Tablek.IDK, Tablek.Emp_Code, Tablek.TXTK1, Foksh_TXTK1() AS at_aziz
FROM Tablek;

لاحظ ان إسم الحقل الأخير (at_aziz) هو من سيعرض القيم ، وسيكون مصدر بيانات مربع النص TXT1 في نموذجك .

 

 

الثاني :-

باستخدام دالةبسيطة مشابهة تقريباً :-

Private Sub Foksh(frm As Form)
    Dim rs As DAO.Recordset
    Dim combinedText As String
    Set rs = frm.RecordsetClone
    rs.MoveFirst
    Do While Not rs.EOF
        If Not IsNull(rs!TXTK1) And rs!TXTK1 <> "" Then
            If combinedText <> "" Then
                combinedText = combinedText & " , "
            End If
            combinedText = combinedText & rs!TXTK1
        End If
        rs.MoveNext
    Loop
    Me.TXT1.Value = combinedText
    rs.Close
    Set rs = Nothing
End Sub

ونستدعيها في حدث "في الحالي - Form_Current" ، بالشكل التالي :-

Private Sub Form_Current()
    Foksh Me
End Sub

 

 

مرفق الحلين :-

 

at_aziz.zip

[at_aziz]

1 ساعه مضت, Foksh said:

حسناً ..

سأقدم لك حلين اثنين ، ولربما سيكون هناك حلول أخرى من الأخوة والساتذة والمعلمين ..

بارك الله فيك وجزاك الله خير اخي الفاضل @Foksh

كل الحلول جميله وتوصل للهدف المطلوب 

الف شكر لك استاذي   

احترامي وتقديري🌹🌹

[منتصر الانسي]

بعد إذن الأخ @Foksh قمت بتعديل المثالين لدمج القيم بدون تكرار

قد يكون هذا التعديل غير ملائم لصاحب السؤال ولكني رأيت وضعه لإثراء الموضوع (وقد يحتاجه أحد الأعضاء مستقبلاً)

تحياتي

at_aziz.rar

[Foksh]

38 دقائق مضت, منتصر الانسي said:

بعد إذن الأخ @Foksh قمت بتعديل المثالين لدمج القيم بدون تكرار

 

فعلاً كلامك صحيح 100% ، وانا اعتمدت على ان الفكرة لن يكون بها تكرار - بسبب بنية الجدول - ، ففي القطعة الواحدة لن يكون لها مثلاً = كوي مكررة ، وهذا ما دعاني لعدم التطرق لفكرة دمج التكرار

[منتصر الانسي]

22 دقائق مضت, Foksh said:

وهذا ما دعاني لعدم التطرق لفكرة دمج التكرار

بالعكس أنت إجابتك هي أنسب حل في هذه الحالة لإنها الأخف والأسرع كونه لايوجد تكرار لأن تعديلي يتطلب إجراءات إضافية للقيام بتصفية القيم المكررة

ولكن وكما ذكرت قمت بإضافته إثراء للموضوع لا أكثر

تحياتي

[Foksh]

31 دقائق مضت, منتصر الانسي said:

ولكن وكما ذكرت قمت بإضافته إثراء للموضوع لا أكثر

 

إثراؤك للموضوع أثار إعجابي ، وأشكرك نيابة عن صاحب الموضوع لما أثريت