هل من الممكن أن تقوم دالة Vlookup بالبحث في شيتين

[zizo747]

أخوتي

أرجوا مساعدتي في تمكين دالة vlookup بالبحث في أكثر من شيت

و شكرا

Officona.rar

[مصطفى كمال]

السلام عليكم ورحمة الله تعالى وبركاته

تفضل أخي الكريم الملف التالي

تم وضع دالة شرطية تحوي دالتين vlookup بحيث في حالةعدم وجود القيمة في الورقة الأولى يبحث في الورقة الثانية

Officona.rar

[عبد الفتاح كيرة]

ضع هذه المعادلة فى b4

=(IF(ISNA(VLOOKUP(A4;'1st Class'!A2:B4;2;0));" not found + ";VLOOKUP(A4;'1st Class'!A2:B4;2;0))&""&(VLOOKUP(Sheet1!A4;'2nd Class'!A2:B4;2;0)))

هذه لإظهار النتيجتين فى خلية واحدة

تم تعديل يناير 14, 2010 بواسطه kemas

[OMRANEAHMED]

السلام عليكم ورحمة الله وبركاته

جزاك الله خيرا

أخي مصطفى كمال

[يحيى حسين]

السلام عليكم و رحمة الله

أخي جرب هذه الدالة

 =LOOKUP(REPT("z",255),CHOOSE({1,2,3},"Not Found",

VLOOKUP(A4,'1st Class'!$A$2:$B$4,2,0),

VLOOKUP(A4,'2nd Class'!$A$2:$B$4,2,0))) 

يحيى حسين.rar

[عبد الفتاح كيرة]

أخى يحيى

لو تكرمت شرحا بسيطا لهذه الألغاز

دالة CHOOSE ترجع لنا 3 قيم

كيف تظهر فى الخلية الاختيار الصحيح من بين هذه الثلاثة

وما فائدة حرف z 255 مرة؟

أظننا مقبلون على فتح عظيم فى معادلات إكسل

جعله الله فى ميزان حسناتك

أخوك كيماس

تم تعديل يناير 16, 2010 بواسطه kemas

[يحيى حسين]

أخي كيماس

لقد أسعدني ردك و طريقة ردك الجميلة

جزاك الله كل خير أخي

==================

بخصوص هذه الدالة و هي دالة وليست ألغاز

استخدمنا الدالة LOOKUP للبحث عن القيمة الرقمية التي نريدها و لكن معيار البحث كان هو الدالة REPT("z",255

و التي ستقوم بتكرار الحرف Z

255 مرة

و الهدف هو حتى تقوم الدالة LOOKUP بالبحث عن اخر قيمة نصية في السلسلة

مع ملاحظة ان هذه الدالة تتجاهل الخطأ إن وجد

أما الدالة CHOOSE إستخدمناها كمرجع للدالة LOOKUP

حيث تقوم ببناء سلسلة من اول نتيجة و التي هي ثابته لدينا "Not Found"

و من ثم إرجاع القيمة من خلال الدالتين VLOOKUP

حيث ستعيد أحدهما نتيجة البحث في حين تعيد الأخرى نتيجة خطأ #N/A

و لتصوير ذلك لو قمنا بوضع اسم محمد في الخلية A4

Mohammed

ستصبح الممعادلة بعد تنفيذ الخطوات السابقة

 =LOOKUP(REPT("z",255),CHOOSE({1,2,3},"Not Found",#N/A,"Pass")) 

و بعد تنفيذ المعادلتين التليتين ستصبح المعادلة

 =LOOKUP("zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz",{"Not Found",#N/A,"Pass"}) 

و من ثم ستقوم الدالة الأساسية LOOKUP بالبحث عن اخر قيمة نصية مع تجاهل الخطأ ========================================== طبعاً يمكننا اختصار المعادلة

 REPT("z",255) 

و لكن استخدامها هكذا حتى تبحث عن أكبر قيمة محتملة مهما بلغ عدد أحرفها مع العلم أيضاً انه في النسخ الحديثة 2007 و 2010 نظراً لزيادة عدد الأحرف المسمومح بها داخل الخلية يمكن استخدام المعادلة التالي حتى تعييد اكبر قيمة نصية ممكنة

 =REPT("z",(2^15)-1) 

=========================================

أتمنى أن أكون قد وفقت في الشرح

و أن يكون لي نصيب من دعائكم

و دمتم في حفظ الله و رعايته

[عبد الفتاح كيرة]

أشكرك جدا أخى يحيى

أما أنك وفقت فى الشرح فهذا واضح جدا

لكن أحيانا لا يفهم المتعلم المبتدئ مثلى

إلا بعد الإجابة عن الأسئلة التى تدور بذهنه

السؤال الأول

الدالة تبحث عن حرف z الأول فتتجاهل الخطأ و تبحث عن الثانى ؟

أم أنها تبحث عن السلسلة ككل و المقصود طولها فقط

السؤال الثانى

الدالة لم تجد معيار البحث ( z 255 مرة) لماذا لا ترجع الخطأ لأن مرجع البحث بعد دالة choose

لا يوجد فيه معيار البحث و هو "z" يعنى الموجود ثلاث قيم ليس فيها "z"

هذا مايدور بذهنى فلو سمح وقتك للرد على أسئلة المبتدئين أكون ممنونا لك

أسأل الله أن يزيدك علما

و أن يرفع قدرك

وجزاك الله خيرا

[خالد القدس]

السلام عليكم

أستاذ مصطفى بارك الله فيك حل رائع

أستاذ يحيى هذه ليست ألغاز فحسب بل وطلاسم ولكنها طلاسم عبقرية لا يفقهها العباقرة أمثالك

ولكن شرحك مميز وواضح إذا لم أفهم هذه الدوال منك فلن استطيع فهمها من غيرك

زادك الله علما على علم ونور على نور

[يحيى حسين]

السلام عليكم و رحمة الله و بركاته <

;السؤال الأولالدالة تبحث عن حرف z الأول فتتجاهل الخطأ و تبحث عن الثانى ؟أم أنها تبحث عن السلسلة ككل و المقصود طولها فقط

أخي تبحث هذه الدالة عن أخر قيمة نصية في السلسلة فلو وجد اي قيمة رقمية او أي خطأ سيتم تجاهلها

;السؤال الثانىالدالة لم تجد معيار البحث ( z 255 مرة) لماذا لا ترجع الخطأ لأن مرجع البحث بعد دالة chooseلا يوجد فيه معيار البحث و هو "z" يعنى الموجود ثلاث قيم ليس فيها "z"

الدالة لا تعيد خطأ لوجود المرجع رقم 1 في الدالة Choose و الذي يعني انه في حال لم تجد الدالتين النتيجة التي تبحثان عنها ستقوم هذه الدالة بإرجاع االمرجع رقم 1 و الذي يحتوي عبارةNot Found

================

أتمنى أن تكون قد إتضحت الصورة لك أخي كيماس

===============

أخي خالد القدس لا ألغاز و لا طلاسم بل هي معادلات و ما زلنا في بداية الطريق مع الإكسيل

تم تعديل يناير 17, 2010 بواسطه يحيى حسين

[احمد فضيله]

أ/ يحيى حسين

بارك الله فيك و جزاك عنا كل خير

[عبد الفتاح كيرة]

شكرا جزيلا للأخ يحيى

و قد بحثت فى الموضوع لأننى أثقلت عليه

لكن له الفضل بعد الله فى اكتشاف هذه الألغاز

و قد توصلت للآتى

الحرف z مكررا 255 مرة هو أكبر قيمة لخلية نصية يمكن تخزينها فى إكسل 2003

بالبحث عن هذه السلسلة طبعا تكون غير موجودة

عندئذ ترجع دالة البحث أقرب قيمة لها أو مساوية لها إن وجدت بشرط أن تكون نصا

و هى آخر خلية نصية فى المرجع مع تجاهل الخطأ

====

وهناك إضافات

* يمكنكم تجربتها

* موقع آخر خلية بها نص فى العمود a

=MATCH(REPT("z";255);A:A)

و لجلب الخلية نفسها

=LOOKUP(REPT("z";255);A:A)

طريقة أخرى

=INDEX(A:A;MATCH(REPT("z";255);A:A))

و لجلب موقع آخر خلية رقمية فى عامود

=MATCH(9.99999999999999E+307;A:A)

و غير ذلك

أرفقت ملفا

وأكرر شكرى للأخ يحيى

جزاه الله خيرا

Book1.zip

تم تعديل يناير 17, 2010 بواسطه kemas

[يحيى حسين]

لم تثقل علي أخي كيماس

بل بالعكس

لقد كنت مستمتعاً بالشرح

و جزاك الله خيرا على إضافتك

و للعلم

 [color="#666600"]=[/color]MATCH[color="#666600"]([/color][color="#006666"]9.99999999999999E+307[/color][color="#666600"];[/color]A[color="#666600"]:[/color]A[color="#666600"])[/color] 

9.99999999999999E+307

يعرف بالـ

BigNumber

و هو أكبر رقم ممكن أن يتعمل معه الإكسيل

و هناك من يشير اليه بطرق مختلفة

1e100

[ahmed fathy2017]

مش عارف اطبق المعادلة دي علي الملف دة .. أرجو من الأخواة الأعزاء مساعدتي .. وشكرا جزيلا

أصابات.rar