طريقة ادخال التاريخ بدون ( / )

[الجزيرة]

السلام عليكم ورحمة الله وبركاته

أخواني ، هل يوجد طريقة لإدخال التاريخ في الخلية بالشكل التالي : 11102011

ليصبح بالتنسيق التالي : 11/10/2011

أي بدون ادخال ( / )

والشكر لكم جميعاً :)

[عبدالله المجرب]

اخي هذه احدى الطرق

اجعل تنسيق الخلية التي ستدخل بها الارقام بتنسيق نص

ثم ضع هذه المعادلة في الخلية B1 بفرض ان خلية الارقام هي A1

=DATE((MID(A1;5;4));MID(A1;3;2);MID(A1;1;2))

ولاحظ النتيجة

ابواحمد

[الجزيرة]

شكراً لك أبو أحمد

طريقة جميلة ، ولكن لو كانت في نفس الخلية التي يتم إدخال الأرقام فيها لكانت أجمل :)

[الـعيدروس]

هذا متوفر في تكست بوكس عن طريف فورم

اما في خليه مااعتقد

[الـعيدروس]

السلام عليكم

اللهم علمنا ماينفعنا

هذا كود تحديد مدى ليعمل ماقلت عنه

ولاكن بهذه الصيغة 010109 اي 01/01/2009

تكتب التاريخ ارقام متواصله وهو يقوم بعمل (/) علامة فواصل التاريخ

ولاكن رجائي من الاساتذه الخبراء التعديل عليه كي يقوم بالفصل في حالة كتابة التاريخ كامل

بمعنى في حالة 8 ارقام الاحتمال الحقيقي 01032011 يعني 01/03/2011

حاولت اعدل عليه ولم انجح

على العموم هذا الكود

Private Sub Worksheet_Change(ByVal Target As Range)

On Error Resume Next

Dim StrVal As String

Dim dDate As Date

    If Target.Cells.Count > 1 Then Exit Sub

    If Intersect(Target, Range("A1:A100")) Is Nothing Then Exit Sub

	 With Target

		 StrVal = Format(.Text, "000000")

		  If IsNumeric(StrVal) And Len(StrVal) = 6 Then

		    Application.EnableEvents = False

		    If Application.International(xlDateOrder) = 1 Then

			    dDate = DateValue(Left(StrVal, 2) & "/" & Mid(StrVal, 3, 2) & "/" & Right(StrVal, 2))

		    Else

			    dDate = DateValue(Mid(StrVal, 3, 2) & "/" & Left(StrVal, 2) & "/" & Right(StrVal, 2))

		    End If

		    .NumberFormat = "dd/mm/yyyy"

		    .Value = CDate(DateSerial(Year(dDate), Month(dDate), Day(dDate)))

		  End If

    End With

	 Application.EnableEvents = True

End Sub

تحياتي

[احمدزمان]

السلام عليكم و رحمة الله

في المرفق كود للأستاذ القدير الفاضل اكسلجي - ابو عبدالله

يعتمد على تسمية نطاق التاريخ باسم Date

آمل ان يفي بالغرض

Private Sub Worksheet_Change(ByVal Target As Excel.Range)

Dim DateStr As String

On Error GoTo EndMacro

If Application.Intersect(Target, Range("date")) Is Nothing Then

    Exit Sub

End If

If Target.Cells.Count > 1 Then

    Exit Sub

End If

If Target.Value = "" Then

    Exit Sub

End If

Application.EnableEvents = False

With Target

If .HasFormula = False Then

    Select Case Len(.Formula)

	    Case 4

		    DateStr = Left(.Formula, 1) & "/" & _

		    Mid(.Formula, 2, 1) & "/" & Right(.Formula, 2)

	    Case 5

		    DateStr = Left(.Formula, 1) & "/" & _

			    Mid(.Formula, 2, 2) & "/" & Right(.Formula, 2)

	    Case 6

		    DateStr = Left(.Formula, 2) & "/" & _

			    Mid(.Formula, 3, 2) & "/" & Right(.Formula, 2)

	    Case 7

		    DateStr = Left(.Formula, 1) & "/" & _

			    Mid(.Formula, 2, 2) & "/" & Right(.Formula, 4)

	    Case 8

		    DateStr = Left(.Formula, 2) & "/" & _

			    Mid(.Formula, 3, 2) & "/" & Right(.Formula, 4)

	    Case Else

		    Err.Raise 0

    End Select

    .Formula = DateValue(DateStr)

End If

End With

Application.EnableEvents = True

Exit Sub

EndMacro:

MsgBox "You did not enter a valid date."

Application.EnableEvents = True

End Sub

وله مشاركة اخرى حول دخال الوقت بدون فواصل

بحثت عنها ولم اجدها حاليا

أسأل الله العلي العظيم ان يكون بخير و في احسن حال

[الجزيرة]

شكراً لك أخي alidroos

على مساهمتك الجميلة :)

------------------

شكراً لك أخي أحمد زمان

على الكود الرائع ، والشكر موصول لحبيبنا الغائب الحاضر / أبو عبد الله

[احمد غانم]

<p style="text-align: center;"><span style="font-size:24px;">السلام عليكم </span></p>

<p style="text-align: center;"><span style="font-size:24px;">عمل رائع سلمت يداك</span></p>

<p style="text-align: center;"><span style="font-size:24px;">سؤالى كيف يمكنني الإستفادة من هذا الكود وغيرة في ملف اكسل ؟</span></p>

<p style="text-align: center;"><span style="font-size:24px;">لكم جزيل الشكرسلفاً</span></p>

[احمد غانم]

السلام عليكم عمل رائع سلمت يداك

سؤالى كيف يمكنني الإستفادة من هذا الكود وغيرة في ملف اكسل

لكم جزيل الشكرسلفاً>

تم تعديل أكتوبر 11, 2011 بواسطه aghanem

[الـعيدروس]

السلام عليكم

استاذ احمد زمان كفيت ووفيت

كود يعمل بكفائة بارك الله فيك

والشكر موصول للاستاذ ابو عبدالله اكسلجي الله يحفظة

تحياتي

[ياسر الحافظ]

الاستاذ احمد زمان

الاستاذ ابو نصار

جزاكم الله كل الخير

الاخ aghanem

جرب نسخ الكود ولصقه في محرر الاكواد ( في حدث الورقة )

وفقكم الله