كيف يمكن جعل الكود يأخذ بيانات من الخلايا

[حسن أبو علي]

سؤالي كيف يمكنني جعل الكود يأخذ البيانات من الخلية.

 

في الكود التالي (الذي كتبه الأستاذ الفاضل ياسر خليل أبو البراء) جزاه الله خيرا

Sub ConvertToVlaues()
    Dim Rng As Range
    Set Rng = Union(Range("C:H"), Range("I:N"))
    Application.ScreenUpdating = False
        Rng.Copy
        Rng.PasteSpecial xlPasteValues
        Range("A1").Select
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
End Sub

نجد أن الأعمدة محددة ، بحيث يقوم بتثبيت بيانات هذه الأعمدة.

 

لكن هل يمكن أن أضع عناوين الأعمدة في خلية في الورقة، ويقوم الكود بأخذ الأسماء الأعمدة من هناك.

 

وذلك حتى أستطيع تغيير أسماء الأعمدة في الخلية بدون الدخول إلى الكود، أو حتى أضع صيغة معينة لوضع عناوين الأعمدة.

 

وشكرا.

Pupils' Names.zip

[ياسر خليل أبو البراء]

أخي الكريم جرب الكود التالي ..

يتم كتابة حروف الأعمدة في الخلية A3

كما هو مبين بالمرفق ..

Sub ConvertToVlaues()
    Dim Col_array As Variant
    Dim I As Long
    
    Col_array = Range("A3").Value
    Col_array = Split(Col_array, ",")
    
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
        For I = LBound(Col_array) To UBound(Col_array)
            With ActiveSheet.Columns(Col_array(I))
                .Copy
                .PasteSpecial xlPasteValues
            End With
        Next I
        Range("A1").Select
    Application.CutCopyMode = False
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
End Sub

تقبل تحياتي

Pupils' Names.rar

[حسن أبو علي]

شكرا لك أستاذي الفاضل