كيف نضيف أدوت جديدة؟

[عبدالعزيز محمد]

السلام عليكم ورحمة الله

أدرت إضافة بعض الأوات وعندما فتحت محرر الاكواد وعند القائمة-TOOLS- اخترت الأمر -additional controls- لم يستجب الأمر

كيف نحل هذه المشكلة مع العلم استخدم النسخة العربية للأوفيس 2010

 

 

[ياسر خليل أبو البراء]

جرب الكود التالي عله يفي بالغرض

Public Sub RenameMSFormsFiles()
    Const tempFileName As String = "MSForms - Copy.exd"
    Const msFormsFileName As String = "MSForms.exd"
    
    On Error Resume Next
    
    RenameFile Environ("TEMP") & "\Excel8.0\" & msFormsFileName, Environ("TEMP") & "\Excel8.0\" & tempFileName
    RenameFile Environ("TEMP") & "\VBE\" & msFormsFileName, Environ("TEMP") & "\VBE\" & tempFileName
    
    MsgBox "Please Restart Excel To Check If ActiveX Controls Are Working Again.", vbInformation
End Sub

Private Sub RenameFile(fromFilePath As String, toFilePath As String)
    If CheckFileExist(fromFilePath) Then
        DeleteFile toFilePath
        Name fromFilePath As toFilePath
    End If
End Sub

Private Function CheckFileExist(path As String) As Boolean
    CheckFileExist = (Dir(path) <> "")
End Function

Private Sub DeleteFile(path As String)
    If CheckFileExist(path) Then
        SetAttr path, vbNormal
        Kill path
    End If
End Sub

فم بعمل ريستارت للإكسيل

فإذا ظلت المشكلة كما هي فأنصحك بتغيير النسخة وتنصيب نسخة جديدة أخرى

[عبدالعزيز محمد]

السلام عليكم ورحمة الله

أين نضع كل هذه الاكواد هل تكون في موديول واحد أم ماذا نأمل التوضيح أكثر بشأن مكان وضع الأكواد السابقة.

 

 

[ياسر خليل أبو البراء]

ضعها في موديول واحد ونفذ الماكرو الأول المسمى RenameMSFormsFiles