فرز أبجدى لورقتين مختلفتين

**أبو سجده** · أكتوبر 16, 2017

السلام عليكم ورحمته الله وبركاته
بداية جزاكم الله خيرا وبارك الله فيكم جميعا ورزقنا واياكم من حيث لانحتسب
المرفق عبارة عن ثلاثة اوراق " الرئيسية - شرط اول - شرط ثانى" حيث تم نقل البيانات من الرئيسية اعتمادا على شرطين
الشرط الاول لنقل البيانات من الورقة الرئيسية الى ورقة العمل " شرط اول" الاعمدة من 1 الى 5 + الاعمدة 7 و23 و18 و 45 اعتمادا على العمود رقم 16
الشرط الثانى لنقل البيانات من الورقة الرئيسية الى ورقة العمل " شرط ثانى" الاعمدة من 1 الى 5 + العمود 18 اعتمادا على العمود رقم 17
والسؤال كيف يمكن اضافة كود لفرز الاسماء أبجديا إعتمادا على العمودين C و D للورقتين شرط اول وشرط ثانى اثناء نقل البيانات
تقبلوا وافر تقديرى واحترامى وجزاكم الله خيرا

فرز أبجدى لعدة أوراق.xlsb.rar

**ابراهيم الحداد** · أكتوبر 17, 2017

السلام عليكم ورحمة الله

انسخ الكودين التالين والصقهما فى الموديول واربط الكود الاول بالزر المتاح

Option Explicit
Sub Trdata_TwoCnds1()
Dim Arr As Variant, Temp As Variant
Dim LR As Long, i As Long, ii As Long, j As Long, jj As Long, P As Long, R As Long
LR = Sheets("الرئيسية").Range("C" & Rows.Count).End(xlUp).Row
Arr = Sheets("الرئيسية").Range("A8:AS" & LR).Value
ReDim Temp(1 To UBound(Arr, 1), 1 To UBound(Arr, 2))
For i = 1 To UBound(Arr, 1)
If Arr(i, 16) = "الاول" Then
P = P + 1
For j = 1 To 9
Temp(P, j) = Arr(i, Choose(j, 1, 2, 3, 4, 5, 7, 23, 18, 45))
Next
End If
Next
Sheets("شرط اول").Range("A8").Resize(P, UBound(Temp, 2)).Value = Temp
Call Trdata_TwoCnds2
End Sub
Sub Trdata_TwoCnds2()
Dim Arr As Variant, Temp As Variant
Dim LR As Long, i As Long, ii As Long, j As Long, P As Long, R As Long
LR = Sheets("الرئيسية").Range("C" & Rows.Count).End(xlUp).Row
Arr = Sheets("الرئيسية").Range("A8:AS" & LR).Value
ReDim Temp(1 To UBound(Arr, 1), 1 To UBound(Arr, 2))
For i = 1 To UBound(Arr, 1)
If Arr(i, 17) = "الثانى" Then
R = R + 1
For j = 1 To 6
Temp(R, j) = Arr(i, Choose(j, 1, 2, 3, 4, 5, 18))
Next
End If
Next
Sheets("شرط ثانى").Range("A8").Resize(R, UBound(Temp, 2)).Value = Temp
End Sub

**أبو سجده** · أكتوبر 17, 2017

وعليكم السلام ورحمته الله وبركاته

اخى العزيز الاستاذ الفاضل // زيزو العجوز

بارك الله فيكم ورزقكم الله تعالى وايانا من حيث لانحتسب ومتعكم الله تعالى بالصحة والعافية

حاولت جاهدا تضمين الكود المرسل من سيادتكم بهذا الكود المبين بالمرفق التالى ولكنى لم أُفلح

ربما لعدم ايصال المطلوب بالشكل الجيد لذا أرجو من سيادتكم مد يد العون فى هذا الطلب

المرفق التالى هو لنقل البيانات من الورقة الرئيسية الى ورقتين بشرطين مختلفين مع ادراج فواصل الصفحات وترك 4 صفوف فارغة للتذييل

والكود يعمل بطريقة ممتازة ولكنى فى حاجة الى إضافة كود لفرز وفلترة البيانات اعتمادا على العمودين C و D بكلا الورقتين " شرط اول و شرط ثانى "

برجاء تنفيذ الكود بالورقة شرط اول ولاحظ ألية عمل الكود وقد أعددت ورقتين للنتائج المتوقعة

أسأل الله تعالى أن يُلهمك من علمه وفضله على ماهو أفضل

ارجو الاطلاع والافادة بحول الله تعالى وجزاكم الله تعالى عنى خير الجزاء **** تقبل وافر تقديرى واحترامى

نقل البيانات من الرئيسية الى ورقتين بشرطين مختلفين مع ادراج فواصل الصفحات وترك 4 صفوف فارغة للتذييل.xlsb.rar

تم تعديل أكتوبر 17, 2017 بواسطه عبدالرحمن وسلمى

**أبو سجده** · أكتوبر 18, 2017

للرفع

**أبو سجده** · أكتوبر 18, 2017

للرفع

**أبو سجده** · أكتوبر 19, 2017

للرفع

**أبو سجده** · أكتوبر 21, 2017

للرفع

**ابراهيم الحداد** · أكتوبر 21, 2017

السلام عليكم ورحمة الله

اخى الكريم / ابو عبد الرحمن وسلمى

اعتذر عن التأخر فى الرد لانشغالى فى الفترة السابقة

عند الاطلاع على الملف الاخير المرسل من قبلكم تأكدت انه

يحمل افضل الحلول التى يمكن الوصول اليها

ولا يحتاج لاى تعديل

هذا وبالله التوفيق

**أبو سجده** · أكتوبر 21, 2017

وعليكم السلام ورحمته الله وبركاته

اخى العزيز الفاضل // زيزو العجوز

ليس هناك مايدعو للإعتذار واعانكم الله ورزقكم وايانا من حيث لانحتسب

تنويه هام المقصد من " على ماهو أفضل " هو أن تصل سيادتكم لحل أفضل من المرفق خاصتى

وكل ما أحتاجه اضافة كود سواء فى الكود المرسل من سيادتكم أو الكود المبين فى المرفق خاصتى

يتولى عملية فرز الاسماء أبجديا كما هو موضح بالورقتين " النتيجة للشرط الاول " و " النتيجة للشرط الثانى " كنتائج متوقعه

تقبل وافر تقديرى واحترامى وجزاكم الله خيرا

**أبو سجده** · أكتوبر 23, 2017

للرفع

تم تعديل أكتوبر 23, 2017 بواسطه عبدالرحمن وسلمى

**أبو سجده** · أكتوبر 23, 2017

للرفع

**أبو سجده** · أكتوبر 29, 2017

للرفع

**أسامة البراوى** · أكتوبر 30, 2017

السلام عليكم

الاخ الفاضل ابو عبد الرحمن وسلمى

اظن ان طلبك هو ترتيب الناتج ابجديا ولذلك قمت بعمل الحل التالى لترتيب الشيت الرئيسي فى شيت مؤقت ثم اعادة اخذ البيانات منه وبالتالى قد تم ترتيب المخرجات بترتيب ابجدى بالكامل وليس داخل كل صفحة كما المرفق .

واتمنى ان يكون ذلك الحل يفى بالغرض

نقل البيانات من الرئيسية الى ورقتين بشرطين مختلفين مع ادراج فواصل الصفحات وترك 4 صفوف فارغة للتذييل- والترتيب.rar

**أبو سجده** · أكتوبر 30, 2017

وعليكم السلام ورحمته الله وبركاته

اخى واستاذى الفاضل // اسامة البراوى

بداية جزاكم الله خيرا وشاكر فضل حضرتك للإهتمام بالرد فجزاكم الله عنى خير الجزاء

فعىلا ظن حضرتك فى محلة بشأن ترتيب المخرجات أبجديا فى كلا الورقتين شرط اول وثانى

اطمع بعد طلب الاذن من سيادتكم فى اضافة او ربما تعديل من شأنه

ابجدة كل مجموعة اسماء تتبع لجهة عمل واحدة بمعنى فرضا

لو هناك على سبيل المثال المرفق 14 موظف تابعين لجهة السلام الاسم الاول يبدأ باسم احمد حامد وتنتهى عند هدى ابراهيم

المجموعة الثانية تابعة لجهة الحرية تبدأ من احمد سعد وتنهى عند هويدا نصر وهكذا فى كلا الورقتين

برجاء الاطلاع على المرفق التالى والاطلاع على خلايا العمودين J و K لتوضيح فكرة هذا الجزء

فيما عدا ذلك فالامور تسرى على مايرام ***** تقبل وافر تقديرى واحترامى وجزاكم الله خيرا

نقل البيانات من الرئيسية الى ورقتين بشرطين مختلفين مع ادراج فواصل الصفحات وترك 4 صفوف فارغة للتذييل- والترتيب.rar

تم تعديل أكتوبر 30, 2017 بواسطه عبدالرحمن وسلمى

**أسامة البراوى** · أكتوبر 31, 2017

السلام عليكم ورحمة الله وبركاته

قم ياضافة السطر التالى للكود لاضافة الترتيب بعمود اخر

WS.Sort.SortFields.Add Key:=Range("D8", "D" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal

     Dim WS As Worksheet
        Set WS = Sheets.Add(After:=Sheets(Worksheets.Count))
        WS.Range("A8", "AS" & LR) = ARR
        

   		WS.Sort.SortFields.Clear
        WS.Sort.SortFields.Add Key:=Range("D8", "D" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        WS.Sort.SortFields.Add Key:=Range("c8", "c" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        
        With WS.Sort
            .SetRange Range("A8", "AS" & LR)
            .Header = xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With

**أبو سجده** · أكتوبر 31, 2017

وعليكم السلام ورحمته الله وبركاته

اخى واستاذى الفاضل // اسامة البراوى

اعتذر استاذى الفاضل للتأخير فى الرد على سيادتكم نظرا لمحاولاتى العديدة فى اكتشاف

عدم ادراج حدود الجدوال بالورقة " شرط اول " فمع اضافة السطر المشار اليه بعاليه

يحدث أمر ما فى عدم ادراج حدود الجدوال بالورقة شرط اول ومع حذفه تعود الامور الى نصابها

WS.Sort.SortFields.Add Key:=Range("D8", "D" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal

علما سيادتكم ان هناك نطاقين مطاطين بالتسمية Creterial 1 و Creterial 2 يمكن لسيادتكم بعد طلب الاذن الاطلاع عليهما من الــ Name Manager

لاستخدامهما فى التنسيقات الشرطية لنطاق الطباعة فى الورقتين شرط اول وشرط ثانى من الصف رقم 8 الى الصف 1048576
فربما يكون هناك ما أغفوا عنه ***** برجاء الاطلاع والافادة بإذن الله تعالى ***** تقبل وافر تقدير واحترامى **** وجزاكم الله خيرا

نقل البيانات من الرئيسية الى ورقتين بشرطين مختلفين مع ادراج فواصل الصفحات وترك 4 صفوف فارغة للتذييل- والترتيب.xlsb.rar

**أسامة البراوى** · نوفمبر 1, 2017

السلام عليكم

لا اخفى عليك انى رايت تلك المشكله لكن ظننت انها فى جهازى فقط لذلك ارسلت لك الكود لتجربته لانى لم يتسع لى الوقت للبحث حينها .. لكنك اشرت الى الحل اعلاه وهو الخاصية

Creterial 1 و Creterial 2

100 والسر هو ان الخواص السابقة تعتمد بشكل اساسى على مكان اكبر رقم فى خانة المسلسل وهى العمود الاول وللصدفة فان اكبر مسلسل فى ورقة العمل"شرط اول" هو

وبسب الترتيب ظهرت فى الصفحة الاولى من الطباعه وبالتالى قامت الخاصية بتحديد مجال الطباعة على الصفحة الاولى فقط اما فى ورقة العمل الاخرى فقد كان مكان اقصى مسلسل وهو 95 في الصفحة

الثانية وبالتالى لم تتكرر المشكلة

والحل بسيط وهو تجاهل تلك الخواص واستبدال الاسطر التالية

.PageSetup.PrintArea = [Criteria1].Address

بالسطر

.PageSetup.PrintArea = Range("A1", "I" & 29 * i + 7).Address

.PageSetup.PrintArea = [Criteria2].Address

بالسطر

.PageSetup.PrintArea = Range("A1", "F" & 34 * i + 7).Address

**أبو سجده** · نوفمبر 1, 2017

وعليكم السلام ورحمته الله وبركاته

اخى واستاذى الفاضل // اسامة البراوى

بداية جزاكم الله خيرا ورزقنا الله واياكم من حيث لانحتسب

صراحة مش عايز اتعب حضرتك أكتر من كده

تم اجراء التعديلات المشار اليها بعاليه وتم إضافة هذا السطر لمراقبة ترتيب العمود D

WS.Sort.SortFields.Add Key:=Range("D8", "D" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal

وتبين أن مشكلة عدم إدراج حدود الجدوال بورقة العمل " شرط اول " قائمة

فهل من محاولة أخرى هذا بعد طلب الاذن **** ولله الامر من قبل ومن بعد

تقبل وافر تقديرى واحترامى **** وجزاكم الله خيرا

تم تعديل نوفمبر 1, 2017 بواسطه عبدالرحمن وسلمى

**أسامة البراوى** · نوفمبر 1, 2017

السلام عليكم

اخى العزيز

حتى لا نظل ندور فى حلول متعددة ونفقد مميزات الكود الاصلى يمكنك التنازل عن ترحيل المسلسل كما هو فى الجدول الرئيسي بحيث يبدا كل جدول فرعي (شرط اول و شرط ثانى ) بمسلسل جديد من 1 وحتى عدد الصفوف المطابقة وبهذا يعمل الكود الاصلى بدون اي مشاكل كما بالكود التالى

Option Explicit
Sub TransferdataByTwoConditions()
    Dim LR As Long, x As Long, i As Long, j As Long, z As Long, zz As Long
    Application.ScreenUpdating = 0
    With Sheets("الرئيسية")
        LR = .Range("A" & Rows.Count).End(xlUp).Row
        ReDim Arr(1 To LR, 1 To 45)
        ReDim SS(1 To LR, 1 To 9)
        ReDim SS2(1 To LR, 1 To 9)
        Arr = .Range("A8", "AS" & LR).Value
        
        Dim WS As Worksheet
        Set WS = Sheets.Add(After:=Sheets(Worksheets.Count))
        
        WS.Range("A8", "AS" & LR) = Arr
        WS.Sort.SortFields.Clear

        WS.Sort.SortFields.Add Key:=Range("D8", "D" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        WS.Sort.SortFields.Add Key:=Range("C8", "C" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        
        With WS.Sort
            .SetRange Range("A8", "AS" & LR)
            .Header = xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        
        Arr = WS.Range("A8", "AS" & LR).Value
        Application.DisplayAlerts = False
        WS.Delete
        Application.DisplayAlerts = True
        
        i = 1: j = 1
        For x = 1 To UBound(Arr)
            If Arr(x, 16) = "الاول" Then
                SS(i, 1) = i: SS(i, 2) = "'" & Arr(x, 2): SS(i, 3) = Arr(x, 3): SS(i, 4) = Arr(x, 4): SS(i, 5) = Arr(x, 5)
                SS(i, 6) = Arr(x, 7): SS(i, 7) = Arr(x, 23): SS(i, 8) = Arr(x, 18): SS(i, 9) = Arr(x, 45)
                z = z + 1
                If z = 25 Then
                                    z = 0: i = i + 5
                Else
                    i = i + 1
                End If
            End If
            If Arr(x, 17) = "الثانى" Then
                SS2(j, 1) = j: SS2(j, 2) = "'" & Arr(x, 2): SS2(j, 3) = Arr(x, 3): SS2(j, 4) = Arr(x, 4): SS2(j, 5) = Arr(x, 5)
                SS2(j, 6) = Arr(x, 18)
                zz = zz + 1
                If zz = 30 Then
                    zz = 0: j = j + 5
                Else
                    j = j + 1
                End If
            End If
        Next
         
         With Sheets("شرط اول")
            LR = .Range("A" & Rows.Count).End(xlUp).Row
            If LR > 6 Then .Range("A8", "I" & LR).ClearContents
            .Range("A8").Resize(UBound(Arr), 9) = SS
            For i = 1 To Application.RoundUp((Application.Match(9 ^ 9, .Range("A:A"), 1) - 7) / 29, 0)
                .HPageBreaks.Add Before:=Cells(29 * i + 8, 1)
                .Cells(29 * i + 4, 2) = "مراجع أول": .Cells(29 * i + 4, 3) = "مراجع ثاني"
                .Cells(29 * i + 4, 5) = "مراجع ثالث": .Cells(29 * i + 4, 7) = "مراجع رابع"
                .Cells(29 * i + 4, 9) = "مراجع خامس"
                .PageSetup.PrintArea = [Criteria1].Address
                .PageSetup.PrintTitleRows = "$1:$7"
                
                
                
            Next
        End With
        With Sheets("شرط ثانى")
            LR = .Range("A" & Rows.Count).End(xlUp).Row
            If LR > 6 Then .Range("A8", "I" & LR).ClearContents
            .Range("A8").Resize(UBound(Arr), 9) = SS2
            For i = 1 To Application.RoundUp((Application.Match(9 ^ 9, .Range("A:A"), 1) - 7) / 34, 0)
                .HPageBreaks.Add Before:=Cells(34 * i + 8, 1)
                .Cells(34 * i + 4, 2) = "مراجع أول": .Cells(34 * i + 4, 3) = "مراجع ثاني"
                .Cells(34 * i + 4, 4) = "مراجع ثالث": .Cells(34 * i + 4, 6) = "مراجع رابع"
                .PageSetup.PrintArea = [Criteria2].Address
                .PageSetup.PrintTitleRows = "$1:$7"
            Next
        End With
    End With
End Sub

**أبو سجده** · نوفمبر 1, 2017

وعليكم السلام ورحمته الله وبركاته

ياحبيبى والله العظيم حضرتك أدب وذوق وأخلاق

يارب يارب يارب ميحرمنيش من حضرتك

جاء ظنى فى محله بشأن تسلسل الورقتين كما أخبرت سيادتكم برسالتى

اطمع فى نقطتين بعد إذن حضرتك

النقطة الاولى هى كيف يمكن جعل السلسلة النصية الخاصة بالتوقيعات فى كلا الورقتين فى الــ Center

النقطة الثانية كيف يمكن التحكم فى ارتفاع الصفوف وعرض الاعمدة حتى استطيع ضبط ورقتى العمل للطباعة

تقبل وافر تقديرى واحترامى الشديد لحضرتك وجزاكم الله خيرا

تم تعديل نوفمبر 1, 2017 بواسطه عبدالرحمن وسلمى

**أسامة البراوى** · نوفمبر 2, 2017

السلام عليكم

بالنسبة لارتفاع الصفوف وعرض الخلايا : دى عملية من الافضل انك تعملها يدوى اول مرة حسب الطابعة الخاصة بك وابعاد ورق الطباعة ولن تتغير لان الكود لايقترب منها

طبعا عدد الصفوف فى كل ورقة عمل انت محدده مسبق

اما بالنسبة للسلسلة النصية فيمكن تطبيق الكود التالى بدلا من الموجود مسبقا لتوزيع التوقيعات

.Cells(29 * i + 4, 1) = "مراجع أول" & String(25, " ") & "مراجع ثاني" & String(25, " ") & "مراجع ثالث" & String(25, " ") & "مراجع رابع" & String(25, " ") & "مراجع خامس"
                .Range("A" & 29 * i + 4, "I" & 29 * i + 4).HorizontalAlignment = xlCenterAcrossSelection

والكود بالكامل سيصبح كالتالى

Option Explicit
Sub TransferdataByTwoConditions()
    Dim LR As Long, x As Long, i As Long, j As Long, z As Long, zz As Long
    Application.ScreenUpdating = 0
    With Sheets("الرئيسية")
        LR = .Range("A" & Rows.Count).End(xlUp).Row
        ReDim Arr(1 To LR, 1 To 45)
        ReDim SS(1 To LR, 1 To 9)
        ReDim SS2(1 To LR, 1 To 9)
        Arr = .Range("A8", "AS" & LR).Value
        
        Dim WS As Worksheet
        Set WS = Sheets.Add(After:=Sheets(Worksheets.Count))
        
        WS.Range("A8", "AS" & LR) = Arr
        WS.Sort.SortFields.Clear

        WS.Sort.SortFields.Add Key:=Range("D8", "D" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        WS.Sort.SortFields.Add Key:=Range("C8", "C" & LR), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        
        With WS.Sort
            .SetRange Range("A8", "AS" & LR)
            .Header = xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        
        Arr = WS.Range("A8", "AS" & LR).Value
        Application.DisplayAlerts = False
        WS.Delete
        Application.DisplayAlerts = True
        
        i = 1: j = 1
        For x = 1 To UBound(Arr)
            If Arr(x, 16) = "الاول" Then
                SS(i, 1) = i: SS(i, 2) = "'" & Arr(x, 2): SS(i, 3) = Arr(x, 3): SS(i, 4) = Arr(x, 4): SS(i, 5) = Arr(x, 5)
                SS(i, 6) = Arr(x, 7): SS(i, 7) = Arr(x, 23): SS(i, 8) = Arr(x, 18): SS(i, 9) = Arr(x, 45)
                z = z + 1
                If z = 25 Then
                                    z = 0: i = i + 5
                Else
                    i = i + 1
                End If
            End If
            If Arr(x, 17) = "الثانى" Then
                SS2(j, 1) = j: SS2(j, 2) = "'" & Arr(x, 2): SS2(j, 3) = Arr(x, 3): SS2(j, 4) = Arr(x, 4): SS2(j, 5) = Arr(x, 5)
                SS2(j, 6) = Arr(x, 18)
                zz = zz + 1
                If zz = 30 Then
                    zz = 0: j = j + 5
                Else
                    j = j + 1
                End If
            End If
        Next
         
         With Sheets("شرط اول")
            LR = .Range("A" & Rows.Count).End(xlUp).Row
            If LR > 6 Then .Range("A8", "I" & LR).ClearContents
            .Range("A8").Resize(UBound(Arr), 9) = SS
            For i = 1 To Application.RoundUp((Application.Match(9 ^ 9, .Range("A:A"), 1) - 7) / 29, 0)
                .HPageBreaks.Add Before:=Cells(29 * i + 8, 1)
                .Cells(29 * i + 4, 1) = "مراجع أول" & String(25, " ") & "مراجع ثاني" & String(25, " ") & "مراجع ثالث" & String(25, " ") & "مراجع رابع" & String(25, " ") & "مراجع خامس"
                .Range("A" & 29 * i + 4, "I" & 29 * i + 4).HorizontalAlignment = xlCenterAcrossSelection
                .PageSetup.PrintArea = [Criteria1].Address
                .PageSetup.PrintTitleRows = "$1:$7"
                
                
                
            Next
        End With
        With Sheets("شرط ثانى")
            LR = .Range("A" & Rows.Count).End(xlUp).Row
            If LR > 6 Then .Range("A8", "I" & LR).ClearContents
            .Range("A8").Resize(UBound(Arr), 9) = SS2
            For i = 1 To Application.RoundUp((Application.Match(9 ^ 9, .Range("A:A"), 1) - 7) / 34, 0)
                .HPageBreaks.Add Before:=Cells(34 * i + 8, 1)
                .Cells(34 * i + 4, 1) = "مراجع أول" & String(15, " ") & "مراجع ثاني" & String(15, " ") & "مراجع ثالث" & String(15, " ") & "مراجع رابع" & String(15, " ") & "مراجع خامس"
                .Range("A" & 34 * i + 4, "F" & 34 * i + 4).HorizontalAlignment = xlCenterAcrossSelection
            
                .PageSetup.PrintArea = [Criteria2].Address
                .PageSetup.PrintTitleRows = "$1:$7"
            Next
        End With
    End With
End Sub

**أبو سجده** · نوفمبر 2, 2017

وعليكم السلام ورحمته الله وبركاته

اخى واستاذى الفاضل // اسامة البراوى

لو أننى أوتيت كل بلاغة وأفنيت بحر النطق فى النظم والنثر

لما كنت بعد القول إلا مقصر ومعترف بالعجز عن واجب الشكر

بارك الله فيكم وفى من تحب ورزقكم الله وإيانا من حيث لانحتسب

تقبل وافر تقديرى واحترامى الشديد جدا جدا جدا لشخصكم المحترم ***** وجزاكم الله خيرا

تم تعديل نوفمبر 2, 2017 بواسطه عبدالرحمن وسلمى

**أبو سجده** · نوفمبر 2, 2017

اخى واستاذى الفاضل // اسامة البراوى

السلام عليكم ورحمته الله وبركاته

متعكم الله تعالى بالصحة والعافية ورزقكم من حيث لاتحتسب

بعد طلب الاذن من حضرتك ملحوظة بسيطة بشأن الرقم المسلسل بالورقتين شرط اول وشرط ثانى

أخى الحبيب المحترم احتمال وارد أن يتحقق الشرطان بالورقة الرئيسية على سبيل المثال على جدولين كاملين وعددهم 40 موظف

تمت التجربة على هذا الجزء ولكن لاحظت المسلسل على هذا النحو

الجدول الاول بالورقة شرط اول انتهى عند رقم 25 اما بداية الجدول الثانى بدأ من الرقم 30 والمفترض ان يبدأ من 26

الجدول الاول بالورقة شرط ثانى انتهى عند رقم 30 اما بداية الجدول الثانى بدأ من الرقم 35 والمفترض ان يبدأ من 31

فهل من سبيل لمعالجة جزئية الترقيم التلقائى

جزاكم الله خيرا **** تقبل وافر تقديرى واحترامى

نقل البيانات من الرئيسية الى ورقتين بشرطين مختلفين مع ادراج فواصل الصفحات وترك 4 صفوف فارغة للتذييل- والترتيب.xlsb.rar

**أسامة البراوى** · نوفمبر 3, 2017

نقل البيانات من الرئيسية الى ورقتين بشرطين مختلفين مع ادراج فواصل الصفحات وترك 4 صفوف فارغة للتذييل- والترتيب.xlsb.rar

**أبو سجده** · نوفمبر 3, 2017

اخى واستاذى الفاضل // اسامة البراوى

السلام عليكم ورحمته الله وبركاته

متعكم الله تعالى بالصحة والعافية ورزقكم من حيث لاتحتسب

الله يبارك لك يا أستاذ اسامة والله بجد اعجز عن شكرى لحضرتك على اهتمامكم وعلى صبركم معى

فجزاكم الله تعالى عنى خير الجزاء وجعله فى ميزان حسناتكم بإذن الله

تقبل وافر تقديرى واحترامى وجزاكم الله خيرا

تسجيل الدخول

فرز أبجدى لورقتين مختلفتين

الردود الموصى بها

انشئ حساب جديد او قم بتسجيل دخولك لتتمكن من اضافه تعليق جديد

انشئ حساب جديد

تسجيل دخول

محتوي مشابه

تصفح هذا الموضوع مؤخراً 0 اعضاء متواجدين الان

Important Information