اضافة على الكود

[عمر الجزاوى]

عملت كود عند اختيارك احد الاصناف يندرج مباشرة الى الفاتورة ولكن عندى مشكلة ان كان الزبون محتاج من الصنف 5 قطع المفروض اضغطت على الصنف 5 مرات يكتب الصنف مرة واحدة ويكتب فى عمود عدد الضغطات وهى 5 ولكن عندى صنف زيتون الحواج عندما ضغطت عليه كرر الصنف المطلوب تعديل ان لا يكرر الصنف  بمعنى كلما ضعطت على نفس الصنف مرة يكتب 1 فى عمود الكمية ان ضغطت مرتين يكتب 2 وهكذا وشكرا على تعاونكم معنا

تعديل على الكود.xlsm

[lionheart]

It is better to use doubleclick event. Try the following code in the worksheet module

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim x, m As Long
    Cancel = True
    If Not Intersect(Target, Range("J11:L20")) Is Nothing Then
        Application.EnableEvents = False
            x = Application.Match(Target, Columns(2), 0)
            If Not IsError(x) Then
                Cells(x, 6) = Cells(x, 6) + 1
            Else
                m = Range("B" & Rows.Count).End(xlUp).Row + 1
                Cells(m, 2) = Target.Value
                Cells(m, 6) = Cells(m, 6) + 1
            End If
        Application.EnableEvents = True
    End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim lr As Long
    If Not Intersect(Target, Range("A11:H30")) Is Nothing Then
        Application.EnableEvents = False
            lr = Target.Row
            Range("B1").Value = lr
            With Shapes("Edit")
                .Left = Sheets(1).Range("i" & lr).Left - 32
                .Top = Sheets(1).Range("i" & lr).Top
                .Visible = msoCTrue
            End With
            With Shapes("Delete")
                .Left = Sheets(1).Range("i" & lr).Left - 16
                .Top = Sheets(1).Range("i" & lr).Top
                .Visible = msoCTrue
            End With
        Application.EnableEvents = True
    End If
End Sub

 

[عمر الجزاوى]

ما شاء الله عليك ياستاذ أسأل الله لكم القبول والخير كله ظاهره وباطنه