مساعدة في ضبط فورم

[mohamedyousef]

السلام عليكم ورحمة الله

السادة الكرام لو سمحتوا احتاج الى مساعدة في الملف المرفق يوجد به اكثر من فورم المشكلة في انه عند فتح الملف يكون على صفحة الرصيد الثابت وافورم يعمل بنجاح وعندما اريد الدخول الى صفحة الادخال وعند اختيار اللون من القائمة لايوجد بها بيانات فلابد ان اكون واقف على صفحة الادخال حتى تظهر البانات فانا اريد من خلال صفحة الفورم الرئيسية وعند اختيار اللون من صفحة الدخول تظهر اتمنى ان يكون شرحي وصل الى سيادتكم

ولسيادتكم وافر التحية

 

مخزون.xlsm

[محمد هشام.]

وعليكم السلام ورحمة الله تعالى وبركاته 

بعد المعاينة يبدوا لي انك بحاجة لتعديل اكواد اليوزرفورم 1 و 2 لانهم لهم نفس المشكلة عدم اظهار البيانات عند الانتقال الى ورقة الادخال تفصل اخي بالنسبة لليوزرفورم 1 قم باظافة الكود التالي 

Private Sub UserForm_Activate()
  Set f = Sheets("الدخول")
  Set d = CreateObject("Scripting.Dictionary")
  Set WSdata = f.[a3].CurrentRegion.Offset(1)
  ' العمود ("CF")
  Search_column = 84
  For i = 3 To WSdata.Rows.Count
     clé = WSdata.Cells(i, Search_column): d(clé) = ""
  Next i
  On Error Resume Next
  Me.Combobox1.List = d.keys
  On Error GoTo 0
End Sub

اما بالنسبة لليوزرفورم 2 قم بحدف جميع الاكواد الموجودة عليه وقم بنسخ الكود التالي 

 

Private Sub TextBox1_Change()
Dim w As Integer, Last&
If Me.TextBox1.Text = Empty Then
Me.ListBox1.Visible = False
ListBox1.Clear
Else
Me.ListBox1.Visible = True
Last = Sheet2.Cells(Rows.Count, 4).End(xlUp).Row
w = 0
For Each c In Sheet2.Range("D2:D" & Last)
If c Like Me.TextBox1.Text & "*" Then
Me.ListBox1.AddItem
Me.ListBox1.List(w, 0) = Sheet2.Cells(c.Row, 4).Value
w = w + 1
End If
Next c
End If
End Sub
Private Sub CommandButton2_Click()
Dim sh1 As Worksheet, f As Range
Set sh1 = Sheet2
  
  With Me.cl
    If .Value = Empty Then
    Exit Sub
End If
    
    Set f = sh1.Range("D:D").Find(.Value, , xlValues, xlWhole, , , False)
    If Not f Is Nothing Then
      Me.fk.Value = sh1.Range("H" & f.Row).Value
      Me.fm.Value = sh1.Range("I" & f.Row).Value
      Me.fq.Value = sh1.Range("J" & f.Row).Value
    End If
  End With
End Sub
Private Sub ListBox1_Click()
Me.cl.Text = Me.ListBox1.Column(0)
Me.ListBox1.Visible = False
Me.TextBox1.Text = ""
End Sub
Private Sub CommandButton1_Click()
Unload Me
End Sub

 

مخزون V2.xlsm

[mohamedyousef]

الف شكر استاذي الفاضل على المساعدة جزاك الله كل خير واسمحلي لو توقفت معي بعض الاوامر اكون شاكر للمساعدة

السلام عليكم اخي الكريم

[محمد هشام.]

اخي حاول فتح موضوع جديد بطلبك وان شاء الله سنحاول مساعدتك قدر المستطاع