✨ هدية ~ مواقيت الصلاة 2024 ✨

[Foksh]

السلام عليكم ورحمة الله وبركاته ، أخواني وأساتذتي ومعلمينا ( دون استثناء )

كنت قد بحثت في المنتدى 🔍 (هنا) عن برامج لعرض مواقيت الصلاة ، وقد وجدت الكثير من المواضيع الجميلة والأفكار النيرة في المنتدى لأساتذة وأخوة بذلوا جهداً لا يوصف في مشاركاتهم بهذا الموضوع ، وإلى حد ما أكثرهم قرباً لضبط الأوقات كانت هذه المشاركة .

 

اليوم الفكرة مختلفة قليلاً في هذا المشروع المتواضع والذي لا يحتوي تعقيدات يصعب قراءتها أو التعامل معها في الأكواد . حيث اعتمدت وتوجهت إلى البساطة من حيث عند النقل والدمج ( إلى / في ) أي مشروع . الآن شرح بسيط لبعض تفاصيل المشروع التي سيتم الإعتماد عليها :-

سي

 سيتم الإعتماد على خطوط الطول والعرض بعد إجراء بعض التعديلات على طريقة احتساب الأوقات . وقد تمت المقارنة مع موقع ( مواقيت الصلاة ) للوصول إلى أقل فارق - إن وُجِد - في المواقيت .

 سيتم الإعتماد على تقويم أم القرى في أحدى مشاركات أستاذنا @ابوخليل .

 سيتم اعتماد إظهار الوقت المتبقي لكل موعد صلاة في الشاشة الرئيسية أو المصغرة ( ستضاف لاحقاً ) .

 سيتم منح الحرية للمستخدم بنوع التذكير لوقت الصلاة ( إشعار برسالة تنبيه داخل البرنامج ، إشعار فوق شريط Taskbar ) .

 سيتم أيضاً منح الحرية للمستخدم باختيار صوت التنبيه ( أذان كامل ، تكبير ، .... إلخ ) .

 المزيد من الأمور ستأتي لاحقاً تباعاً في تطويرات وتحديثات جديدة إن شاء الله .

 

صورة لواجهة البرنامج حالياً ، والذي أسميته في الوقت الحالي " صلوات " 🤗 ، ما لم يتم اختيار اسم آخر  

 

 

 

 

تم تعديل April 21 بواسطه Foksh
تم إزالة المرفق مؤقتاً

[عبد اللطيف سلوم]

57 دقائق مضت, Foksh said:

السلام عليكم ورحمة الله وبركاته ، أخواني وأساتذتي ومعلمينا ( دون استثناء )

كنت قد بحثت في المنتدى 🔍 (هنا) عن برامج لعرض مواقيت الصلاة ، وقد وجدت الكثير من المواضيع الجميلة والأفكار النيرة في المنتدى لأساتذة وأخوة بذلوا جهداً لا يوصف في مشاركاتهم بهذا الموضوع ، وإلى حد ما أكثرهم قرباً لضبط الأوقات كانت هذه المشاركة .

 

اليوم الفكرة مختلفة قليلاً في هذا المشروع المتواضع والذي لا يحتوي تعقيدات يصعب قراءتها أو التعامل معها في الأكواد . حيث اعتمدت وتوجهت إلى البساطة من حيث عند النقل والدمج ( إلى / في ) أي مشروع . الآن شرح بسيط لبعض تفاصيل المشروع التي تم الإعتماد عليها :-

 

 تم الإعتماد على خطوط الطول والعرض بعد إجراء بعض التعديلات على طريقة احتساب الأوقات . وقد تمت المقارنة مع موقع ( مواقيت الصلاة ) للوصول إلى أقل فارق - إن وُجِد - في المواقيت .

 تم الإعتماد على تقويم أم القرى في أحدى مشاركات أستاذنا @ابوخليل .

 تم اعتماد إظهار الوقت المتبقي لكل موعد صلاة في الشاشة الرئيسية أو المصغرة ( ستضاف لاحقاً ) .

 سيتم منح الحرية للمستخدم بنوع التذكير لوقت الصلاة ( إشعار برسالة تنبيه داخل البرنامج ، إشعار فوق شريط Taskbar ) .

 سيتم أيضاً منح الحرية للمستخدم باختيار صوت التنبيه ( أذان كامل ، تكبير ، .... إلخ ) .

 المزيد من الأمور ستأتي لاحقاً تباعاً في تطويرات وتحديثات جديدة إن شاء الله .

 

صورة لواجهة البرنامج حالياً مع الملف المرفق ، والذي أسميته في الوقت الحالي " صلوات " 🤗 ، ما لم يتم اختيار اسم آخر  

Salawat.accdb 2.06 \u0645\u064a\u062c\u0627 \u0628\u0627\u064a\u062a · 2 downloads

 

 

 

طلع عندي هيك

ما في اوقات للصلوات ؟؟

[abouelhassan]

شكر وتقدير واحترام من اخيك 

[Foksh]

أخواني واساتذتي ، ما زال العمل على المشروع قيد التطوير  🤗

[SAROOK]

بارك الله فيك وجزاك خيرا ورحم الله والدك

[الهمة]

عمل رائع أتمنى لك التوفيق

[Foksh]

استكمالاً لما سبق 👆 :-

بطريقة بسيطة سيتم الاعتماد على حساب الجيب العكسي للزوايا باستخدام دالة الرمز الجيبي العكسي (Arcsine)، والتي يُرمز لها بـ ASin . تُستخدم الدالة ASin في الرياضيات لحساب الزاوية التي تمثلها الجيب العكسي لنسبة محددة من الجانب المقابل لزاوية مثلث، عندما يُعرف طول الضلع المقابل لهذه الزاوية . ويتمثل ذلك في المعادلة الرياضية  . صورة تعبيرية

وبناءً على هذه المعادلة سيتم احتساب أوقات الصلاة باستخدام معادلات فلكية و جيوغرافية ، ومن ثم سنعيد القيمة الراجعة بتنسيق معين بشكل وقت . حسب المديول التالي ، والذي يعتبر عامود المشروع وقوامه وأساسه :-

 

Option Compare Database
    Const PI As Double = 3.14159265358979

Function ASin(Value As Double) As Double
    If Abs(Value) <> 1 Then
        ASin = Atn(Value / Sqr(1 - Value * Value))
    Else
        ASin = 1.5707963267949 * Sgn(Value)
    End If
End Function
Public Function ACos(ByVal nValue As Double, Optional fRadians As Boolean = True) As Double
        ACos = -Atn(nValue / Sqr(1 - nValue * nValue)) + PI / 2
        If fRadians = False Then ACos = ACos * (PI / 180)
End Function

Function gettimes(lag As Double, lat As Double, tzon As Double, stime As String, method As Integer, Optional dylt As Integer = 0, Optional strdate As Date) As Date
    ' تعريف المتغيرات المستخدمة
    Dim D, L, m, lambda, alpha, noon, alt, UTNoon, localNoon, st, Dec, ar, obl As Double
    
    ' حساب تاريخ اليوم
    D = (367 * Year(strdate)) - Int(((Year(strdate) + Int((Month(strdate) + 9) / 12)) * 7) / 4) + Int(275 * Month(strdate) / 9) + Day(strdate) - 730531.5
    
    ' حساب زاوية الشمس والشروق والغروب
    L = 280.461 + 0.9856474 * D
    L = L - (360 * Int(L / 360))
    m = 357.528 + 0.9856003 * D
    m = m - (360 * Int(m / 360))
    lambda = L + 1.915 * Sin(m * PI / 180) + 0.02 * Sin(2 * m * PI / 180)
    obl = 23.439 - 0.0000004 * D
    
    ' حساب موضع الشمس وزاوية الشروق والغروب
    alpha = Atn(Cos(obl * PI / 180) * Tan(lambda * PI / 180)) * 180 / PI
    alpha = alpha - (360 * Int(alpha / 360))
    alpha = alpha + 90 * (Fix(lambda / 90) - Fix(alpha / 90))
    st = 100.46 + 0.985647352 * D
    st = st - (360 * Int(st / 360))
    Dec = ASin(Sin(obl * PI / 180) * Sin(lambda * PI / 180)) * 180 / PI
    noon = alpha - st
    noon = noon - (360 * Int(noon / 360))
    UTNoon = noon - lag
    localNoon = (UTNoon / 15) + tzon + dylt
    
    ' حساب أوقات الصلاة
Select Case stime
    Case Is = "Fajr"
        ' حساب وقت الفجر
        alt = DLookup("FajrDegree", "PrayerCalculation", "MethodType=" & method & "")
        ar = ACos((Sin(alt * PI / 180) - Sin(Dec * PI / 180) * Sin(lat * PI / 180)) / (Cos(Dec * PI / 180) * Cos(lat * PI / 180))) * 180 / PI
        fajr = localNoon - ar / 15
        gettimes = Format(fajr / 24, "hh:nn:ss")
        
    Case Is = "Shrok"
        ' حساب وقت الشروق
        alt = -1
        ar = ACos((Sin(alt * PI / 180) - Sin(Dec * PI / 180) * Sin(lat * PI / 180)) / (Cos(Dec * PI / 180) * Cos(lat * PI / 180))) * 180 / PI
        shrouk = localNoon - ar / 15
        gettimes = Format(shrouk / 24, "hh:nn:ss")
        
    Case Is = "Zohr"
        ' حساب وقت الظهر
        gettimes = Format(localNoon / 24, "hh:nn:ss")
        
    Case Is = "Asr1"
        ' حساب وقت العصر (الطريقة الأولى)
        alt = 90 - Atn(1 + Tan(Abs(lat - Dec) * PI / 180)) * 180 / PI
        ar = ACos((Sin(alt * PI / 180) - Sin(Dec * PI / 180) * Sin(lat * PI / 180)) / (Cos(Dec * PI / 180) * Cos(lat * PI / 180))) * 180 / PI
        asr = localNoon + ar / 15
        gettimes = Format(asr / 24, "hh:nn:ss")
        
    Case Is = "Asr2"
        ' حساب وقت العصر (الطريقة الثانية)
        alt = 90 - Atn(2 + Tan(Abs(lat - Dec) * PI / 180)) * 180 / PI
        ar = ACos((Sin(alt * PI / 180) - Sin(Dec * PI / 180) * Sin(lat * PI / 180)) / (Cos(Dec * PI / 180) * Cos(lat * PI / 180))) * 180 / PI
        asr = localNoon + ar / 15
        gettimes = Format(asr / 24, "hh:nn:ss")
        
    Case Is = "Maghrib"
        ' حساب وقت المغرب
        alt = -1
        ar = ACos((Sin(alt * PI / 180) - Sin(Dec * PI / 180) * Sin(lat * PI / 180)) / (Cos(Dec * PI / 180) * Cos(lat * PI / 180))) * 180 / PI
        maghrib = localNoon + ar / 15
        gettimes = Format(maghrib / 24, "hh:nn:ss")
        
    Case Is = "Eshaa"
        ' حساب وقت العشاء
        If method = 4 Then
            alt = -1
            ar = ACos((Sin(alt * PI / 180) - Sin(Dec * PI / 180) * Sin(lat * PI / 180)) / (Cos(Dec * PI / 180) * Cos(lat * PI / 180))) * 180 / PI
            maghrib = localNoon + ar / 15
            If Month(CStr(Date)) = 9 Then
                gettimes = Format((maghrib + 2) / 24, "hh:nn:ss")
            Else
                gettimes = Format((maghrib + 1.5) / 24, "hh:nn:ss")
            End If
            
        Else
            alt = DLookup("IshaDegree", "PrayerCalculation", "MethodType=" & method & "")
            ar = ACos((Sin(alt * PI / 180) - Sin(Dec * PI / 180) * Sin(lat * PI / 180)) / (Cos(Dec * PI / 180) * Cos(lat * PI / 180))) * 180 / PI
            eshaa = localNoon + ar / 15
            gettimes = Format(eshaa / 24, "hh:nn:ss")
        End If
End Select

End Function

 

يتبع ... 👈

[كمال على طارق]

بارك الله فيك وزادك الله من فضله

[Foksh]

استكمالاً لما سبق 👆 :-

 

 سنبدأ اليوم ببدء تصميم الجداول :-

الجدول الأول جدول Country الخاص بالدول التي سيشملها البرنامج لحساب أوقات الصلاة .

الجدول الثاني جدول City الخاص بالمدن المتفرعة لكل دولة في الجدول السابق .

الجدول الثالث جدول Curcity الخاص بإعدادات المدينة الحالية التي سيتم عرض أوقات الصلاة لها . ( إختصار Current City ) .

الجدول الرابع جدول PrayerCalculation الخاص بطريقة الحساب والمذاهب .... الخ . 

 

المرفق في المشاركة التالية 👇

 

 

يتبع ... 👈

تم تعديل April 22 بواسطه Foksh
نقل المرفق للمشاركة التالية

[Foksh]

استكمالاً لما سبق 👆 :-

 

 تم إنشاء نموذج  Settings المسؤول عن تحديد طريقة احتساب أوقات الصلاة والبلد والمدينة .

 تم البدء بإدراج الأوقات في النموذج الرئيسي Home ، حيث تم الإحتساب بدايةً لوقت شروق الشمس فقط ، وذلك بإضافة جزء من الدالة التي تقوم باحتساب الأوقات بناءً على المديول الرئيسي في المشاركة قبل السابقة 👆.

 

Salawat.accdb

 

يتبع ... 👈

تم تعديل April 23 بواسطه Foksh

[Foksh]

استكمالاً لما سبق 👆 :-

 

 نستكمل العمل على النماذج متابعة على النموذج الرئيسي   ( Home ).

          سنقوم بإنشاء مربع النص ( Fajr ) الذي سيتم عرض وقت الصلاة فيه ، وسنبدأ بوقت صلاة الفجر وكل ما يتبعه . وهذا السطر سيقوم بمهمة حساب الوقت بناءً على الدالة الرئيسية الموجودة في المديول الرئيسي ( في المشاركة الثانية لي 👆 ) ، وسيتم إضافة السطر التالي في الدالة العامة Salawat الموجودة في النموذج Home .

Me.fajr = Format(GetTimes(Me.longitude, Me.latitude, Me.timezone, "Fajr", Me.tx, dt, mydate), "hh:mm AM/PM")

طبعاً السطر سيقوم بجلب ( خط الطول والعرض وفرق التوقيت عن جرينتش و التوقيت الصيفي حسب الدولة ) للمدينة التي تم تحديدها في نموذج الإعدادات سابقاً ، ويقوم باحتساب الوقت عن طريق الدالة GetTimes من المديول . والنتيجة ستكون كما سيتم عرضه في المرفق التالي 😊

❗ ملاحظة :- وقت الفجر الظاهر سيكون هو وقت الأذان الأول .

Salawat.accdb

يتبع ... 👈

تم تعديل April 25 بواسطه Foksh

[Foksh]

استكمالاً لما سبق في النموذج Home 👆 :-

 

          أيضاً سنقوم بإنشاء مربع نص ( Fjr_Eq ) والذي سيتم احتساب وقت الإقامة لصلاة الفجر فيه ، وسيتم أيضاً إضافة سطر هذه الوظيفة في الدالة العامة Salawat الموجودة في النموذج Home ليصبح الكود مع ما سبق كالآتي :-

    Dim mydate As Date, dt As Integer
    mydate = IIf(Me.My_Date = "" Or IsNull(Me.My_Date), Date, Me.My_Date)
    If Me.daylight = True Then dt = 1 Else dt = 0
    Me.fajr = Format(GetTimes(Me.longitude, Me.latitude, Me.timezone, "Fajr", Me.tx, dt, mydate), "hh:mm AM/PM")
    Me.Fjr_Eq = Format(DateAdd("n", 30, CDate(Me.fajr)), "hh:mm AM/PM")
    Me.shrok = Format(GetTimes(Me.longitude, Me.latitude, Me.timezone, "Shrok", Me.tx, dt, mydate), "hh:mm AM/PM")

طبعاً تم إضافة الوقت ما بين الأذان الأول والأذان الثاني ( تقريباً 10 دقائق ) إلى الوقت لما بعد الأذان حتى إقامة الصلاة ( 20 دقيقة للفجر ) وعليه سيصبح مجموع الوقتين ( 30 دقيقة ) بعد موعد الأذان الأول . 

❗ ملاحظة :- أعمل على مراحل في المشروع حسب وقت الفراغ والضغط في العمل ليس إلا  😅 .

 

Salawat.accdb

 

يتبع ... 👈

تم تعديل April 24 بواسطه Foksh

[Foksh]

استكمالاً لما سبق في النموذج Home 👆 :-

 

          نستكمل العمل لضبط الوقت المتبقي لكل صلاة خلال اليوم ، بحيث عندما يحين موعد صلاة الظهر مثلاً يتغير الوقت لإحتساب الوقت المتبقي لصلاة العصر ( وقت تنازلي ) . وهذا العمل من شأن حدث On Timer وعليه فإننا سنخبره انه مقارنة مع الوقت الحالي كم تبقى لحين موعد صلاة الفجر ( على سبيل المثال ) ؟ فسيقوم الكود التالي بحساب جملة الأوقات لكل صلاة وإدراجها في مربع النص الذي سنتحدث عنه وغيره فيما يلي :-

✨ مربع النص Txt_Pry_Name = عرض اسم الوقت الحالي للصلاة ( فجر , ظهر , عصر , مغرب , عشاء ) .

✨ مربع النص Txt_Time_Count = هنا سيتم عرض الوقت المتبقي لكل صلاة بالتنسيق ( 00:00 بعداد تنازلي ) . وحين يتبقى دقيقة واحدة على موعد الأذان سيصبح العداد الزمني بهذا التنسيق ( 00:00:59 ) ويبدأ بالنزول كل ثانية إلى حين موعد الأذان التالي فسيعود إلى التنسيق السابق ( 00:00 ) .

 

          طبعاً حالياً سيتم عرض رسالة عادية فقط عند دخول وقت الصلاة مفادها : ( "حان الآن موعد أذان الفجر" ) . وهذا الكود الذي سيقوم بالمهام التي ذكرتها لكم 

Private Sub Form_Timer()
   
    Dim tfajr As Date, tzohr As Date, tasr As Date, tmagrib As Date, tisha As Date
    Dim dt As Integer
    Dim currentTime As Date, nextPrayerTime As Date, timeLeft As Date
    Dim hoursLeft As Integer, minutesLeft As Integer, secondsLeft As Integer
    Dim fajrTime As Date, Country_Name As String
    
    If Me.daylight = True Then
        dt = 1
    Else
        dt = 0
    End If
    
    tfajr = GetTimes(Me.longitude, Me.latitude, Me.timezone, "fajr", Me.tx, dt, Date)

    currentTime = Time
    fajrTime = CDate(Me.fajr)
    Country_Name = DLookup("[city_name]", "City", "ID=" & [city_name])
    
    If currentTime < fajrTime Then
        Txt_Pry_Name.Value = "الفجر"
        nextPrayerTime = fajrTime
    Else
        Txt_Pry_Name.Value = "الفجر"
        nextPrayerTime = DateAdd("d", 1, fajrTime)
    End If
    
    If currentTime < nextPrayerTime Then
        timeLeft = nextPrayerTime - currentTime
    Else
        timeLeft = DateAdd("h", 24, nextPrayerTime) - currentTime
    End If
    
    hoursLeft = Hour(timeLeft)
    minutesLeft = Minute(timeLeft)
    secondsLeft = Second(timeLeft)
    
    If Me.Txt_Time_Count = "00:00" Then
        Me.Txt_Time_Count = "00:00:59"
        Me.Txt_Time_Count = Format(hoursLeft, "00") & ":" & Format(minutesLeft, "00") & ":" & Format(secondsLeft, "00")
    Else
        Me.Txt_Time_Count = Format(hoursLeft, "00") & ":" & Format(minutesLeft, "00")
    End If
    
    Me.Caption = Country_Name & " " & "بقي لصلاة " & Txt_Pry_Name & " " & Txt_Time_Count & " تقريباً" & " ، في مدينة "
    
    If Time() = tfajr Then
        MsgBox "حان الآن موعد أذان الفجر", , ""
    End If
End Sub

 

Salawat.accdb

يتبع ... 👈

تم تعديل April 26 بواسطه Foksh
حذف جملة تجاوز الخطأ لعدم حاجتها 😊

[Foksh]

استكمالاً لما سبق في النموذج Home 👆 :-

 

          نستكمل العمل لضبط الوقت المتبقي ، و اليوم سنضيف وقت صلاة العشاء وما يتبعه كما يلي :-

✨ في الدالة Salawat داخل النموذج Home ، سنضيف السطرين المسؤولين عن إدراج وقت صلاة العشاء و وقت الإقامة .

    Me.isha = Format(GetTimes(Me.longitude, Me.latitude, Me.timezone, "Eshaa", Me.tx, dt, mydate), "hh:mm AM/PM")
    Me.Ish_Eq = Format(DateAdd("n", 10, CDate(Me.isha)), "hh:mm AM/PM")

حيث سيكون وقت الإقامة 10 دقائق بعد نهاية الأذان .

 

✨ في حدث Form_Timer للنموذج Home سنقوم بحجز المتغير [ishaTime As Date] من نوع Date لصلاة العشاء وقيمته [ishaTime = CDate(Me.isha)] ، والحدث الذي سيقوم باحتساب الوقت المتبقي لموعد صلاة العشاء ؛ ليصبح الكود للحدث كما يلي :-

Private Sub Form_Timer()
    On Error Resume Next
    
    Dim tfajr As Date, tzohr As Date, tasr As Date, tmagrib As Date, tisha As Date
    Dim dt As Integer
    Dim currentTime As Date, nextPrayerTime As Date, timeLeft As Date
    Dim hoursLeft As Integer, minutesLeft As Integer, secondsLeft As Integer
    Dim fajrTime As Date, zohrTime As Date, Country_Name As String, ishaTime As Date
    
    If Me.daylight = True Then
        dt = 1
    Else
        dt = 0
    End If
    
    tfajr = GetTimes(Me.longitude, Me.latitude, Me.timezone, "fajr", Me.tx, dt, Date)

    currentTime = Time
    fajrTime = CDate(Me.fajr)
    zohrTime = CDate(Me.zohr)
    ishaTime = CDate(Me.isha)
    Country_Name = DLookup("[city_name]", "City", "ID=" & [city_name])
    
    If currentTime < fajrTime Then
        Txt_Pry_Name.Value = "الفجر"
        nextPrayerTime = fajrTime
    ElseIf currentTime < zohrTime Then
        Txt_Pry_Name.Value = "الظهر"
        nextPrayerTime = zohrTime
    ElseIf currentTime < ishaTime Then
        Txt_Pry_Name.Value = "العشاء"
        nextPrayerTime = ishaTime
    Else
        Txt_Pry_Name.Value = "الفجر"
        nextPrayerTime = DateAdd("d", 1, fajrTime)
    End If
    
    If currentTime < nextPrayerTime Then
        timeLeft = nextPrayerTime - currentTime
    Else
        timeLeft = DateAdd("h", 24, nextPrayerTime) - currentTime
    End If
    
    hoursLeft = Hour(timeLeft)
    minutesLeft = Minute(timeLeft)
    secondsLeft = Second(timeLeft)
    
    If Me.Txt_Time_Count = "00:00" Then
        Me.Txt_Time_Count = "00:00:59"
        Me.Txt_Time_Count = Format(hoursLeft, "00") & ":" & Format(minutesLeft, "00") & ":" & Format(secondsLeft, "00")
    Else
        Me.Txt_Time_Count = Format(hoursLeft, "00") & ":" & Format(minutesLeft, "00")
    End If
    
    Me.Caption = Country_Name & " " & "بقي لصلاة " & Txt_Pry_Name & " " & Txt_Time_Count & " تقريباً" & " ، في مدينة "
    
    If Time() = tfajr Then
        MsgBox "حان الآن موعد أذان الفجر", , ""
    End If
End Sub

 

Salawat.accdb

يتبع ... 👈

 

تم تعديل الأربعاء at 16:50 بواسطه Foksh
إضافة المرفق

[صالح الصالحي]

السلام عليكم ورحمة الله وبركاته

في  مايكروسوفت اكسس

لدي جدول اسمه "المواقف" يحتوي على حقل اسمه[رقم الموقف ] نوع ترقيم تلقائي وهو مفتاح اساسي  وحقل [ تاريخ الموقف ]وحقل [اليوم ] يرتبط بهذا الجدول اربعة جداول بعلاقة ون تو ميني هي 
١-جدول "اجتماعات العاملين "وهذا الجدول مرتبط به جدول اسمه "حضور الاجتماعات " وانشأت منهما استعلام حتى يقوم بحساب عدد المشاركين في كل اجتماع  
٢-وجدول "الدورات" وهذا مرتبط به جدول اسمه "المشاركين في الدورات " وانشأت منهما استعلام يحسب عدد المشاركين في كل دورة
٣- وجدول "النزول الميداني 
٤-وجدول" المادة التي تم توزيعها" اريد ان يكون هناك نموذج بحث بين تاريخين لطباعة تقرير يومي واسبوعي وشهري وسنوي عندما ادخل تاريخ محدد باليوم مثلا يقوم بعرض التقرير وفي اعمال ذلك اليوم فقط  لاجتماعات ذلك اليوم  ودورات ذلك اليوم ونزول ذلك اليوم و وتوزيع مادة ذلك اليوم وكذلك عندما اقوم بادخال تاريخ اليوم الى بعد سبعة يقوم بعرض ماتم في تلك السبعة الايام وهكذا بالنسبة للشهري والسنوي

[Foksh]

منذ ساعه, صالح الصالحي said:

السلام عليكم ورحمة الله وبركاته

في  مايكروسوفت اكسس

لدي جدول اسمه "المواقف" يحتوي على حقل اسمه[رقم الموقف ] نوع ترقيم تلقائي وهو مفتاح اساسي  وحقل [ تاريخ الموقف ]وحقل [اليوم ] يرتبط بهذا الجدول اربعة جداول بعلاقة ون تو ميني هي 
١-جدول "اجتماعات العاملين "وهذا الجدول مرتبط به جدول اسمه "حضور الاجتماعات " وانشأت منهما استعلام حتى يقوم بحساب عدد المشاركين في كل اجتماع  
٢-وجدول "الدورات" وهذا مرتبط به جدول اسمه "المشاركين في الدورات " وانشأت منهما استعلام يحسب عدد المشاركين في كل دورة
٣- وجدول "النزول الميداني 
٤-وجدول" المادة التي تم توزيعها" اريد ان يكون هناك نموذج بحث بين تاريخين لطباعة تقرير يومي واسبوعي وشهري وسنوي عندما ادخل تاريخ محدد باليوم مثلا يقوم بعرض التقرير وفي اعمال ذلك اليوم فقط  لاجتماعات ذلك اليوم  ودورات ذلك اليوم ونزول ذلك اليوم و وتوزيع مادة ذلك اليوم وكذلك عندما اقوم بادخال تاريخ اليوم الى بعد سبعة يقوم بعرض ماتم في تلك السبعة الايام وهكذا بالنسبة للشهري والسنوي

وعليكم السلام ورحمة الله وبركاته اخي @صالح الصالحي ، التزاماً بقواعد المنتدى ارجو ان تقوم بفتح موضوع جديد لطلبك ، وإن شاء الله ستجد الحلول المناسبة لطلبك 🥰 .

 

كل الشكر والتقدير لك 🤗