خطا في كود SAVE PDF

[hanykassem]

 

السلام عليكم 

يرجي التكرم بالمساعده بعد تغير الويندوز ظهر المشكله دي

CODE

Sub SaveAs_PDF()
NAME1= Range("B2")
NAME3= Range("B3")
NAME3= Range("B4")
Path = "D:\PDF"
fname = NAME1& " - " & NAME2& " - " & NAME3
MsgBox "Saved as PDF "
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, ignoreprintareas:=False, Filename:=Path & fname
End Sub

بتظهر الرساله دي

[محمد هشام.]

وعليكم السلام ورحمة الله تعالى وبركاته 

جرب هذا 

 

Sub SaveAs_PDF()
    Dim NAME1 As String
    Dim NAME2 As String
    Dim NAME3 As String
    Dim Path As String
    Dim fname As String
  
    NAME1 = Range("B2").Value
    NAME2 = Range("B3").Value
    NAME3 = Range("B4").Value
    
    Path = "D:\PDF\"
    
 'إنشاء مجلد الحفظ في حالة عدم وجوده
   ' If Dir(Path, vbDirectory) = "" Then
       ' MkDir Path
   ' End If
    
    fname = NAME1 & " - " & NAME2 & " - " & NAME3 & ".pdf"
    
    MsgBox "Saved as PDF"
    
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=Path & fname, IgnorePrintAreas:=False
End Sub

مع التأكد من تفعيل المراجع الأساسية على مكتبة vba  مثل:

• Visual Basic For Applications
• Microsoft Excel Object Library

تم تعديل أكتوبر 11, 2024 بواسطه محمد هشام.

[hanykassem]

  تسلم ايدك ممكن نضيف رساله  بان لو كان تم عمل  سيف من قبل

رساله ب YES OR NO

وشكرا علي المساعده

تم تعديل أكتوبر 12, 2024 بواسطه hanykassem

[محمد هشام.]

Sub SaveAs_PDF()
    Dim NAME1 As String, NAME2 As String, NAME3 As String
    Dim Path As String, fname As String, FullPath As String
    Dim response As VbMsgBoxResult
  
    NAME1 = Range("B2").Value
    NAME2 = Range("B3").Value
    NAME3 = Range("B4").Value
    
    Path = "D:\PDF\"
    
    If Dir(Path, vbDirectory) = "" Then
        MkDir Path
    End If
    fname = NAME1 & " - " & NAME2 & " - " & NAME3 & ".pdf"
    FullPath = Path & fname
        If Dir(FullPath) <> "" Then
        response = MsgBox("الملف موجود بالفعل هل تريد استبداله؟", vbYesNo + vbQuestion, "تأكيد")
        If response = vbNo Then
            Exit Sub
        End If
    End If

     ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FullPath, IgnorePrintAreas:=False
       MsgBox "Saved As PDF "
End Sub

 

 

TEST SAVE PDF.xlsb

تم تعديل أكتوبر 12, 2024 بواسطه محمد هشام.