اشكال في تمرير قيمة لدالة

[athal1]

Function record(Criteria As String)

    Dim rs As dao.Recordset
    
    Set rs = CurrentDb.OpenRecordset("SELECT * FROM customers")
   
  rs.FindFirst Criteria = City
    
   Do While Not rs.NoMatch
   
     List1.AddItem rs!FirstName
     
        rs.FindNext Criteria = City
      
   Loop
    
    rs.Close
    
End Function
                  
Private Sub Command0_Click()
City = aa
record (City)
End Sub

السلام عليكم

الاساتذة الكرام

يوجد اشكال في تمرير فيمة في دالة

بارك الله فيكم

db1.accdb

تم تعديل يناير 15 بواسطه athal1

[Barna]

جرب هذا

Function record(Criteria As String)

    Dim rs As DAO.Recordset
    Dim db As DAO.Database
    Dim condition As String
    
    ' قم بتعيين قاعدة البيانات الحالية
    Set db = CurrentDb
    Set rs = db.OpenRecordset("SELECT * FROM customers")
    
    ' تحديد الشرط
    condition = "City = '" & Criteria & "'"
    
    rs.FindFirst condition
    
    Do While Not rs.NoMatch
        ' إضافة العنصر إلى القائمة
        List1.AddItem rs!FirstName
        
        ' ابحث عن العنصر التالي
        rs.FindNext condition
    Loop
    
    ' إغلاق السجل
    rs.Close
    Set rs = Nothing
    Set db = Nothing
    
End Function

Private Sub Command0_Click()
    Dim City As String
    
    ' تعيين القيمة للمدينة
    City = "aa"
    
    ' استدعاء الدالة
    record City
End Sub

 

[athal1]

الاستاذالكريم   Barna

تمام  وهذا هو المطلوب بارك الله فيك وجزاك خيرا