تقسيم أرقآم الوحدات بالقدم والبوصة في أكثر من خلية

[م. عمر]

السلام عليكم

هناك خطأ،يجب أن يأخذ العمود الثاني قيمة البوصة فقط، والعمود الثالث قيمة الكسر.

العمود الثالث مثلا هو 1/8 يجب أن يكون 0.125، كيف يمكنني إصلاح هذه المشكلة؟

Architect Units Feet-Inches.xlsx

تم تعديل مارس 21, 2025 بواسطه م. عمر

[م. عمر]

السلام عليكم 

اخي الكريم اعتذر منك انا لم اقصد خطا في المعادلات، وانما اريد التنويه ان خانة الكسر هي 1/8 وتساوي 0.125

والجدول الذي اضفته على اليمين كان يحوي على الارقام التي يجب الحصول عليها من المعادلات 

بعد محاولات عديدة، حصلتُ على ما أحتاجه تمامًا باستخدام معادلاتك. مع ذلك، اضطررتُ إلى استخدام بعض الأعمدة الإضافية للحصول على النتيجة النهائية، ولم أستطع دمجها في معادلة واحدة. كان من الصعب جدًا الحساب باستخدام وحدات القياس كالبوصات والأقدام، لكنني نجحتُ في النهاية! أرفقتُ الملف النهائي تحسبًا لاحتياج أحد إليه في المستقبل.

جزاك الله كل خير

Sum Architect Units Feet-Inches.xlsx

[محمد هشام.]

12 ساعات مضت, م. عمر said:

لم أستطع دمجها في معادلة واحدة. كان من الصعب جدًا الحساب باستخدام وحدات القياس كالبوصات والأقدام

جرب هدا هل يناسبك 

 

=SUM(IF(ISNUMBER(FIND("-",E2:E6)),LEFT(E2:E6,FIND("-",E2:E6)-1) + MID(E2:E6,FIND("-",E2:E6)+1,FIND
(" ",E2:E6&" ")-FIND("-",E2:E6)-1)/12 +
        IFERROR(VALUE("0 "&MID(E2:E6,FIND(" ",E2:E6&" ")+1,LEN(E2:E6)))/12,0),E2:E6/12 ))

 

Sum Architect Units Feet-Inches V2.xlsx

[م. عمر]

هل يمكنك دمج المعادلات في العمود G مع معادلة العمود H وجعلهما معادلة واحدة في العمود H، والشيء نفسه في العمود I+j؟ سيساعدني هذا بشكل أفضل.

[محمد هشام.]

رغم أن هدا لم يكن طلبك في أول مشاركة  لاكنني أعتقد أنه الان قد تم تزويدك بجميع الحلول الممكنة للحصول على النتائج المطلوبة 

تم وضع الصيغ في جدول مستقل لتتمكن من مقارنة النتائج 

 

 صيغ الأعمدة  G + H

=LET(extracted_text, IF(ISNUMBER(FIND("-", E2)), TRIM(MID(E2, FIND("-", E2) + 1, LEN(E2) - FIND("-", E2))), E2),
 NUMBERVALUE(IF(ISNUMBER(FIND(" ", extracted_text)), TRIM(LEFT(extracted_text, FIND(" ", extracted_text) - 1)), extracted_text)))

أو 

=NUMBERVALUE(IF(ISNUMBER(FIND(" ", IF(ISNUMBER(FIND("-", E2)),
TRIM(MID(E2, FIND("-", E2) + 1, LEN(E2) - FIND("-", E2))), E2))), TRIM(LEFT(IF(ISNUMBER(FIND("-", E2)),
TRIM(MID(E2, FIND("-", E2) + 1, LEN(E2) - FIND("-", E2))), E2), FIND(" ", IF(ISNUMBER(FIND("-", E2)),
TRIM(MID(E2, FIND("-", E2) + 1, LEN(E2) - FIND("-", E2))), E2)) - 1)), IF(ISNUMBER(FIND("-", E2)),
TRIM(MID(E2, FIND("-", E2) + 1, LEN(E2) - FIND("-", E2))), E2))))

 

 صيغ الأعمدة  I + J

=(IFERROR(VALUE("0 "&MID(F2,FIND(" ",F2)+1,LEN(F2)-FIND(" ",F2))), 0)) +
(IFERROR(VALUE("0 "& IF(ISNUMBER(FIND(" ",G2)),TRIM(RIGHT(G2,LEN(G2)-FIND(" ",G2))),  0) ), 0))

 بالتوفيق.........

 

 

Sum Architect Units Feet-Inches V3.xlsx

تم تعديل مارس 27, 2025 بواسطه محمد هشام.