اضافة حقل جدول

[2saad]

إخواني الأعزاء بعد سلام الله عليكم ورحمة الله وبركاته

الملف المرفق به جدول اسمه tbl_Temp زودت عليه حقل Stucod وملأته يدويا لكي يظهر في الاستعلام  qry_Temp

ولكن عندما اعمل إعداد لنتيجة الفصل الدراسي الأول أو الفصل الدراسي الثاني من فورم  frm_ResultSetting تختفي البيانات التي سجلتها في حقل Stucod بالجدول tbl_Temp

ما السبب ؟؟ ارجو الحل مع الشرح

بارك الله فيكمData18.rar

 

[Foksh]

وعليكم السلام ورحمة الله وبركاته ،

أخي الكريم @2saad ، الأصل هو تتبع الاستعلامات التي بُنيت عليها الإستعلامات الفرعية ، والأستاذ @ابوخليل مشكوراً أسس لك الإستعلامات بشكل سهل تستطيع منه التتبع والتعديل ... إلخ

على العموم ، في البداية يجب إضافة الحقل في الاستعلام الأصلي = qry_master .

ثانياً ، إضافة الحقل في الاستعلامين (qry_Temp_term1 و qry_Temp_term2 ) .
ثالثاً ، بعد إضافة الحقل Stucod في الجدول ، قمت بالتعديل على زري (اعداد نتيجة الفصل الدراسي الأول و اعداد نتيجة الفصل الدراسي الثاني) بحيث يتم اضافة قيمة الحقل الى الجدول ، كالآتي :-

Private Sub ProcessTermData(termNum As Integer, ctrl As Control, includeVHodor As Boolean)
    On Error GoTo ErrorHandler
    
    ctrl.Caption = "انتظر ..."
    DoCmd.SetWarnings False
    
    DoCmd.RunSQL "DELETE FROM tbl_Temp WHERE tbl_Temp.term_Num = " & termNum & ";"
    
    If includeVHodor Then
        DoCmd.RunSQL "INSERT INTO tbl_Temp (term_Num, vHodor, alnesbah, tgyeem1, hala, safType, eldina_id, Stucod) " & _
                     "SELECT qry_term" & termNum & ".*, qry_Temp_term" & termNum & ".term_Num, " & _
                     "qry_Temp_term" & termNum & ".hodor, qry_Temp_term" & termNum & ".alnesbah1, " & _
                     "qry_Temp_term" & termNum & ".tgyeem1, qry_Temp_term" & termNum & ".hala1, " & _
                     "qry_Temp_term" & termNum & ".safType, qry_Temp_term" & termNum & ".eldina_id, " & _
                     "qry_Temp_term" & termNum & ".Stucod " & _
                     "FROM qry_Temp_term" & termNum & " INNER JOIN qry_term" & termNum & " " & _
                     "ON qry_Temp_term" & termNum & ".Stucard = qry_term" & termNum & ".Stucard;"
    Else
        DoCmd.RunSQL "INSERT INTO tbl_Temp (term_Num, alnesbah, tgyeem1, hala, safType, eldina_id, Stucod) " & _
                     "SELECT qry_term" & termNum & ".*, qry_Temp_term" & termNum & ".term_Num, " & _
                     "qry_Temp_term" & termNum & ".alnesbah1, qry_Temp_term" & termNum & ".tgyeem1, " & _
                     "qry_Temp_term" & termNum & ".hala1, qry_Temp_term" & termNum & ".safType, " & _
                     "qry_Temp_term" & termNum & ".eldina_id, qry_Temp_term" & termNum & ".Stucod " & _
                     "FROM qry_Temp_term" & termNum & " INNER JOIN qry_term" & termNum & " " & _
                     "ON qry_Temp_term" & termNum & ".Stucard = qry_term" & termNum & ".Stucard;"
    End If
    
    DoCmd.SetWarnings True
    ctrl.Caption = "تــم"
    Exit Sub
    
ErrorHandler:
    DoCmd.SetWarnings True
    ctrl.Caption = "خطأ"
    MsgBox "حدث خطأ أثناء معالجة البيانات", vbCritical + vbMsgBoxRight, ""
End Sub

 

ثم الإستدعاء في الزرين :-

Private Sub StartBtn_Click()
    ProcessTermData 1, b, False
End Sub

Private Sub StartBtn2_Click()
    ProcessTermData 2, bb, True
End Sub

ملفك بعد التعديل :-

Data18.zip

 

أو البقاء على الاستعلامات الاصلية للزرين كما في التالي :-

Private Sub StartBtn_Click()
    b.Caption = "انتظر ..."
    DoCmd.SetWarnings False
    DoCmd.RunSQL "DELETE tbl_Temp.*, tbl_Temp.term_Num FROM tbl_Temp WHERE (((tbl_Temp.term_Num)=1));"
    DoCmd.RunSQL "INSERT INTO tbl_Temp (term_Num, alnesbah, tgyeem1, hala, safType, eldina_id, Stucod) " & vbCrLf & _
                "SELECT qry_term1.*, qry_Temp_term1.term_Num, qry_Temp_term1.alnesbah1, qry_Temp_term1.tgyeem1, " & _
                "qry_Temp_term1.hala1, qry_Temp_term1.safType, qry_Temp_term1.eldina_id, qry_Temp_term1.Stucod " & vbCrLf & _
                "FROM qry_Temp_term1 INNER JOIN qry_term1 ON qry_Temp_term1.Stucard = qry_term1.Stucard;"
    
    DoCmd.SetWarnings True
    b.Caption = "تــم"
End Sub

Private Sub StartBtn2_Click()
    bb.Caption = "انتظر ..."
    DoCmd.SetWarnings False
    DoCmd.RunSQL "DELETE tbl_Temp.*, tbl_Temp.term_Num FROM tbl_Temp WHERE (((tbl_Temp.term_Num)=2));"
    DoCmd.RunSQL "INSERT INTO tbl_Temp (term_Num, vHodor, alnesbah, tgyeem1, hala, safType, eldina_id, Stucod) " & vbCrLf & _
                "SELECT qry_term2.*, qry_Temp_term2.term_Num, qry_Temp_term2.hodor, qry_Temp_term2.alnesbah1, " & _
                "qry_Temp_term2.tgyeem1, qry_Temp_term2.hala1, qry_Temp_term2.safType, qry_Temp_term2.eldina_id, qry_Temp_term2.Stucod " & vbCrLf & _
                "FROM qry_Temp_term2 INNER JOIN qry_term2 ON qry_Temp_term2.Stucard = qry_term2.Stucard;"
    
    DoCmd.SetWarnings True
    bb.Caption = "تــم"
End Sub

 

تم تعديل منذ 16 ساعات بواسطه Foksh
اضافة أكثر من حل 😉

[2saad]

شكرا جزيلا أخي الفاضل وبارك الله فيك وفي أستاذنا والأب ذو الخلق الكريم والقلب الطيب استاذنا ومعلمنا ( أبو خليل )