مساعدة فى كود توزيع اللجان

[The best]

السلام عليكم ورحمة الله وبركاته 

فى النموذج الموجود فى الملف المرفق عند الضغط على توزيع لا يتم التنفيذ بعد كتابة المطلوب فى 1 و 2

cont.accdb

[Foksh]

وعليكم السلام ورحمة الله وبركاته..

العنوان ليس ذا دلالة على المشكلة . وبدافع الفضول عند فتح الموضوع نجد أن الشرح لا يوصل المطلوب .

فما هو الذي لا يتم تنفيذه ؟؟؟؟؟  😅

[The best]

10 دقائق مضت, Foksh said:

وعليكم السلام ورحمة الله وبركاته..

العنوان ليس ذا دلالة على المشكلة . وبدافع الفضول عند فتح الموضوع نجد أن الشرح لا يوصل المطلوب .

فما هو الذي لا يتم تنفيذه ؟؟؟؟؟  😅

فى (1) بكتب عدد الطلاب فى كل لجنة وبناء على ذلك بيتم تحديد عدد اللجان 

كما هو يتضح فى مربع انص التالى ( عدد اللجان الممكنة )

وفى (2) بكتب بداية ترقيم اللجان ثم تنفيذ 

لكنه لا يعمل

[Foksh]

طيب ، على حسب ما فهمت من مناقشات سابقة بهذا الخصوص ، جرب هذا التعديل :-

Private Sub أمر322_Click()
    On Error GoTo ErrHandler
    If DCount("*", "data_dor2", "Not IsNull(n_lgna_dor2)") > 0 Then
        MsgBox "عفوا .. تم إضافة وترقيم اللجان من قبل", vbCritical + vbMsgBoxRight, ""
        Exit Sub
    End If

    If IsNull(Me.studen_lg) Or Me.studen_lg <= 0 Then
        MsgBox "عزيزى مدخل البيانات .. من فضلك ضع عدد التلاميذ المطلوبة فى كل لجنة قبل التنفيذ", vbCritical + vbMsgBoxRight, ""
        Exit Sub
    End If

    If IsNull(Me.start_lg) Then
        MsgBox "عزيزى مدخل البيانات من فضلك ضع بداية ترقيم اللجان قبل التنفيذ", vbCritical + vbMsgBoxRight, ""
        Exit Sub
    End If

    Dim rs As DAO.Recordset
    Dim lgCounter As Long
    Dim stdPerGroup As Long
    Dim i As Long

    Set rs = Me.RecordsetClone
    rs.MoveFirst

    lgCounter = Me.start_lg
    stdPerGroup = Me.studen_lg
    i = 0
    Do While Not rs.EOF
        rs.Edit
        rs!n_lgna_dor2 = lgCounter
        rs.Update

        i = i + 1
        If i Mod stdPerGroup = 0 Then
            lgCounter = lgCounter + 1
        End If

        rs.MoveNext
    Loop
    Me.Requery
    MsgBox "تم توزيع الطلاب على اللجان بنجاح", vbInformation + vbMsgBoxRight, ""
    Exit Sub

ErrHandler:
    MsgBox " : حدث خطأ" & Err.Description, vbCritical + vbMsgBoxRight, ""
End Sub