كيف يتم إزالة علامة (X) التكبير وليس التعطيل

[أبو عبير 2005]

الإخوة الكرام 

 

السلام عليكم ورحمة الله وبركاته

 

إخواني كيف يتم إزالة علامة ( X )  وعلامة التكبير وهي علامة الإغلاق الإفتراضية في النموذج  . 

 

إخواني أريد الإزالة وليس التعطيل . 

 

كما أريد الإبقاء على علامة تضغير النموذج فقط .

 

 

 

 

كل عام وأنتم بخير .

[.Azhar]

لاحظ الشرح في الصورة المرفقة 

[أبو عبير 2005]

يا مرحبا بالغالي

لكن أخي الغالي أنا أريد زر التصغير .

[.Azhar]

اجعل الاول نعم والاخر لا 

بمعنى الكونترول بوكس نعم 

سوف يظهر لديك X لكن لا يعمل 

[أبو عبير 2005]

حياك الله وحفظك

الله يبارك فيك وفي ذريتك

أخي الغالي لكن أنا حددت في مشاركتي أريد إزالة علامة

الخروج والتكبير وليس التعطيل .

تقبل فائق تقديري واحترامي .

[.Azhar]

طيب لكن هذا الشي لا تستطيع فعله الا بداله او وحدة نمطية وهذه الوحدة النمطية سوف تزيل لك كل علامة الخروج في الاكسس نفسه وفي فرومات برنامجك . 

سوف ارفق لك الكود البرمجي للوحدة النمطية .

Private Declare Function SetWindowLong Lib "user32" Alias _
                                       "SetWindowLongA" (ByVal hWnd As Long, ByVal nindex As Long, _
                                                         ByVal dwnewlong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias _
                                       "GetWindowLongA" (ByVal hWnd As Long, ByVal nindex As Long) As Long
Const WS_MINIMIZEBOX = &H20000
Const WS_MAXIMIZEBOX = &H10000
Const WS_CLOSEBOX = &H80000
Const GWL_STYLE = (-16)
Sub RemoveMaxMinCloseBoxes()
   Dim M As Long
   Dim hWnd As Long
   hWnd = Application.hWndAccessApp
   M = GetWindowLong(hWnd, GWL_STYLE)
   M = M And Not (WS_MINIMIZEBOX)
   M = M And Not (WS_MAXIMIZEBOX)
   M = M And Not (WS_CLOSEBOX)
   M = SetWindowLong(hWnd, GWL_STYLE, M)
End Sub
Sub RestoreMaxMinCloseBoxes()
   Dim M As Long
   Dim hWnd As Long
   hWnd = Application.hWndAccessApp
   M = GetWindowLong(hWnd, GWL_STYLE)
   M = M Or (WS_MINIMIZEBOX)
   M = M Or (WS_MAXIMIZEBOX)
   M = M Or (WS_CLOSEBOX)
   M = SetWindowLong(hWnd, GWL_STYLE, M)
End Sub

استدعاء الدالة 

Private Sub Form_Load()
   RemoveMaxMinCloseBoxes
End Sub

[.Azhar]

اما من ناحية التكبير والتصغير . فيمكن بالنقر المزدوج على شريط النافذه , 

تحياتي لك . 

[أبو عبير 2005]

بارك الله فيك وفي ذريتك

أخي أنا لا أريد تكبير البرنامج

أنا فقط أريد زر التصغير فقط .

لا أريد الخروج ولا أريد التكبير .

ولا أريد تعطيلها بل أريد حذفها .

تقبل فائق تقديري واحترامي .

[.Azhar]

ابو عبير هل جربت الوحدة النمطية ام لا هذه الداله لا تكبر ولا تصغر النافذه بل تلغي خاصية X ولا يمكن غلق البرنامج لا من النافذه ولا من الاكسس لان حتى علامة Xالخاصة ببرنامج الاكسس سوف تلغى , لذا يجب وضع زر خاص بك للخروج من البرنامج . 

[.Azhar]

انظر لهذا المثال 

 

HedX.rar

[.Azhar]

وهذا الكود لاخفاء الاكسس وجعل واجهاتك فقط تظهر . 

لكن يعمل هذا الكود فقط على 2007 و 2010 

Private Sub Form_Load()
DoCmd.ShowToolbar "Ribbon", acToolbarNo
DoCmd.ShowToolbar "Status Bar", acToolbarNo
DoCmd.NavigateTo "acNavigationCategoryObjectType"
DoCmd.RunCommand acCmdWindowHide
End Sub

[.Azhar]

وهذه اكواد بلغة API لكل خاصية يمكنك ان تختار من يبقى ومن يحذف .

Sub HideMaxMin()
    Dim lngStyle As Long
    lngStyle = GetWindowLong(hWndAccessApp, GWL_STYLE)
    lngStyle = lngStyle And Not WS_MINIMIZEBOX
    lngStyle = lngStyle And Not WS_MAXIMIZEBOX
    Call SetWindowLong(hWndAccessApp, GWL_STYLE, lngStyle)
    Call SetWindowPos(hWndAccessApp, HWND_TOP, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE Or SWP_DRAWFRAME)
End Sub
Sub ShowMinMax()
    Dim lngStyle As Long
    lngStyle = GetWindowLong(hWndAccessApp, GWL_STYLE)
    lngStyle = lngStyle Or WS_MINIMIZEBOX
    lngStyle = lngStyle Or WS_MAXIMIZEBOX
    Call SetWindowLong(hWndAccessApp, GWL_STYLE, lngStyle)
    Call SetWindowPos(hWndAccessApp, HWND_TOP, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE Or SWP_DRAWFRAME)
End Sub
Sub DisableMax()
    Dim lngStyle As Long
    lngStyle = GetWindowLong(hWndAccessApp, GWL_STYLE)
    lngStyle = lngStyle And Not WS_MAXIMIZEBOX
    Call SetWindowLong(hWndAccessApp, GWL_STYLE, lngStyle)
    Call SetWindowPos(hWndAccessApp, HWND_TOP, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE Or SWP_DRAWFRAME)
End Sub
Sub EnableMax()
    Dim lngStyle As Long
    lngStyle = GetWindowLong(hWndAccessApp, GWL_STYLE)
    lngStyle = lngStyle Or WS_MAXIMIZEBOX
    Call SetWindowLong(hWndAccessApp, GWL_STYLE, lngStyle)
    Call SetWindowPos(hWndAccessApp, HWND_TOP, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE Or SWP_DRAWFRAME)
End Sub
Sub DisableMin()
    Dim lngStyle As Long
    lngStyle = GetWindowLong(hWndAccessApp, GWL_STYLE)
    lngStyle = lngStyle And Not WS_MINIMIZEBOX
    Call SetWindowLong(hWndAccessApp, GWL_STYLE, lngStyle)
    Call SetWindowPos(hWndAccessApp, HWND_TOP, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE Or SWP_DRAWFRAME)
End Sub
Sub EnableMin()
    Dim lngStyle As Long
    lngStyle = GetWindowLong(hWndAccessApp, GWL_STYLE)
    lngStyle = lngStyle Or WS_MINIMIZEBOX
    Call SetWindowLong(hWndAccessApp, GWL_STYLE, lngStyle)
    Call SetWindowPos(hWndAccessApp, HWND_TOP, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE Or SWP_DRAWFRAME)
End Sub