خطأ فى الكود

[محمد عبد القادر]

برجاء توضيح الخطأ فى هذا الكود و لكم سلفا وافر الشكر 

 

Function searchcriteria()

Dim strtype, strgender As String

Dim task, strcriteria As String

If IsNull(Me.cbotype) Then

strtype = "[type] like ' * ' "

Else

strtype = "[type]= ' " & Me.cbotype & " ' "

End If

If IsNull(Me.cbogender) Then

strgender = "[gender] like ' * ' "

Else

strgender = "[gender]= ' " & Me.cbogender & " ' "

End If

strcriteria = strtype & "and" & strgender

task = "select * from tbl_customers where " & strcriteria

Me.customers_subform.Form.RecordSource = task

Me.customers_subform.Form.Requery

End Function

المحاولة الرابعة.rar

[jjafferr]

وعليكم السلام 

 

تفضل ياسيدي 

واضفت لك حركة ، فلما تريد تحذف بيانات بحث احد الحقلين ، انقر عليه مرتين ، وراح يتصفى 

Option Compare Database

Private Sub cbogender_AfterUpdate()
    
    Call searchcriteria
End Sub

Private Sub cbogender_DblClick(Cancel As Integer)

    Me.cbogender = ""
    Call searchcriteria
End Sub

Private Sub cbotype_AfterUpdate()
    
    Call searchcriteria
End Sub
Function searchcriteria()

    Dim strtype, strgender As String
    Dim task, strcriteria As String

    If Len(Me.cbotype & "") = 0 Then
        strtype = "[type] like '*'"
    Else
        strtype = "[type]= '" & Me.cbotype & "'"
    End If
    'Debug.Print strtype
    

    If Len(Me.cbogender & "") = 0 Then
        strgender = "[gender] like '*'"
    Else
        strgender = "[gender]= '" & Me.cbogender & "'"
    End If
    'Debug.Print strgender

    strcriteria = strtype & " and " & strgender
    task = "select * from tbl_customers where " & strcriteria
    Me.customers_subform.Form.RecordSource = task
    Me.customers_subform.Form.Requery
    
End Function


Private Sub cbotype_DblClick(Cancel As Integer)

    Me.cbotype = ""
    Call searchcriteria
End Sub

Private Sub Form_Load()

    Me.cbotype = ""
    Me.cbogender = ""
End Sub

 

 

جعفر

263.المحاولة الرابعة.accdb.zip

[محمد عبد القادر]

الأخ الفاضل شكر الله لك و جزاكم الله الخير كله