مطلوب اظهار الساعة تعمل داخل النموذج (الساعة والدقائق والثواني ) من غير استخدام عداد (تايمر) النموذج

[ابوخليل]

السلام عليكم

المطلوب كما في العنوان

Database1.accdb

[ابو جودي]

وعليكم السلام ورحمة الله تعالى وبركاته
استاذى الجليل و معلمى القدير و والدى الحبيب

الكود التالى فى وحده نمطية عامة
 

Option Compare Database
Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Function SetTimer Lib "user32" _
        (ByVal hWnd As LongPtr, ByVal nIDEvent As LongPtr, _
         ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As LongPtr

    Private Declare PtrSafe Function KillTimer Lib "user32" _
        (ByVal hWnd As LongPtr, ByVal nIDEvent As LongPtr) As Long
#Else
    Private Declare Function SetTimer Lib "user32" _
        (ByVal hWnd As Long, ByVal nIDEvent As Long, _
         ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long

    Private Declare Function KillTimer Lib "user32" _
        (ByVal hWnd As Long, ByVal nIDEvent As Long) As Long
#End If

Private lngTimerID As LongPtr
Private frmTargetClock As Form

Public Sub StartSystemClock(frm As Form)
    Set frmTargetClock = frm
    lngTimerID = SetTimer(0, 0, 1000, AddressOf TimerProc)
End Sub

Public Sub StopSystemClock()
    If lngTimerID <> 0 Then
        KillTimer 0, lngTimerID
        lngTimerID = 0
    End If
End Sub

Private Sub TimerProc(ByVal hWnd As LongPtr, ByVal uMsg As Long, ByVal idEvent As LongPtr, ByVal dwTime As Long)
    If Not frmTargetClock Is Nothing Then
        frmTargetClock!lblClock.Caption = Format(Now, "hh:nn:ss AM/PM")
    Else
        StopSystemClock
    End If
End Sub

الاحدات فى النموذج
 

Option Compare Database
Option Explicit

Private Sub Form_Load()
    Call StartSystemClock(Me)
End Sub


Private Sub Form_Unload(Cancel As Integer)
    Call StopSystemClock
End Sub

 

المرفق

 

Clock Without Timer Event.accdb

[ابوخليل]

13 دقائق مضت, ابو جودي said:

وعليكم السلام ورحمة الله تعالى وبركاته

استاذى الجليل و معلمى القدير و والدى الحبيب

الكود التالى فى وحده نمطية عامة

انت الأستاذ وانت المعلم وانت الأبن الحبيب

ينتهي المقال عند عرض المثال

الف شكر باشمهند وفيت وكفيت

 هذا الكود او بالاصح قريبا منه كان عندي وحاولت التعامل معه داخل النموذج ولم افلح

[ابو جودي]

8 دقائق مضت, ابوخليل said:

 هذا الكود او بالاصح قريبا منه كان عندي وحاولت التعامل معه داخل النموذج ولم افلح

استاذى الجليل و معلمى القدير و والدى الحبيب

دوال api  لا يتم الاعلان عنها داخل النماذج
او بشكل ادق وأصح : AddressOf لابد ان يكون داخل وحده نمطيه عامة

[ابو جودي]

استاذى الجليل و معلمى القدير و والدى الحبيب الاستاذ @ابوخليل 

أهديكم هذا المرفق 

يحتوى على الساعتين الرقمية والعقارب وبدون حدث الوقت 
وبه هديه لتعيير ثيم النموذج كذلك
 

AnalogClock Without Timer Event.zip

[ابوخليل]

عمل رائع وجميل

وحدات نمطية وأكواد  متعوب عليها

في اعمالي اقتصر غالبا قدر استطاعتي على الادوات التي يملكها اكسس .. 

فالساعة مثلا لا اخرج عن هذا السطر:

Private Sub Form_Timer()
Me.Label2.Caption = Format(Now, "hh:nn:ss AM/PM")
End Sub

ولكني وظفت العداد في عملية مهمة لضبط الإدخال في عملية الحضور

وقد جعلت الفورم يملأ الشاشة .. فكانت فكرة اظهار الساعة مستحسن ومناسب

الفكرة التي راودتني حين طرحت الموضوع هي .. هل يمكنني جلب ساعة  وندز الى الفورم بسطر واحد ؟

مثل سطر جلب مستخدم وندوز :

CreateObject("WScript.Network").UserName

او رقم المعالج :

Environ("NUMBER_OF_PROCESSORS")

واشياء اخرى يمكن جلبها او تشغيلها ومناداتها بسطر